pkgs/applications/networking/irc/tiny/default.nix

   1 { stdenv
   2 , lib
   3 , rustPlatform
   4 , fetchFromGitHub
   5 , pkg-config
   6 , Foundation
   7 , dbusSupport ? stdenv.hostPlatform.isLinux, dbus
   8 # rustls will be used for TLS if useOpenSSL=false
   9 , useOpenSSL ? stdenv.hostPlatform.isLinux, openssl
  10 , notificationSupport ? stdenv.hostPlatform.isLinux
  11 }:
  12
  13 rustPlatform.buildRustPackage rec {
  14   pname = "tiny";
  15   version = "0.12.0";
  16
  17   src = fetchFromGitHub {
  18     owner = "osa1";
  19     repo = "tiny";
  20     rev = "v${version}";
  21     hash = "sha256-VlKhOHNggT+FbMvE/N2JQOJf0uB1N69HHdP09u89qSk=";
  22   };
  23
  24   cargoHash = "sha256-AhQCfLCoJU7o8s+XL3hDOPmZi9QjOxXSA9uglA1KSuY=";
  25
  26   nativeBuildInputs = lib.optional stdenv.hostPlatform.isLinux pkg-config;
  27   buildInputs = lib.optionals dbusSupport [ dbus ]
  28                 ++ lib.optionals useOpenSSL [ openssl ]
  29                 ++ lib.optional stdenv.hostPlatform.isDarwin Foundation;
  30
  31   buildFeatures = lib.optional notificationSupport "desktop-notifications";
  32
  33   meta = with lib; {
  34     description = "Console IRC client";
  35     homepage = "https://github.com/osa1/tiny";
  36     changelog = "https://github.com/osa1/tiny/blob/v${version}/CHANGELOG.md";
  37     license = licenses.mit;
  38     maintainers = with maintainers; [ Br1ght0ne vyp ];
  39     mainProgram = "tiny";
  40   };
  41 }