pkgs/applications/networking/mpop/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , gnutls
   5 , openssl
   6 , gsasl
   7 , libidn
   8 , pkg-config
   9 , Security
  10 , nlsSupport ? true
  11 , idnSupport ? true
  12 , gsaslSupport ? true
  13 , sslLibrary ? "gnutls"
  14 }:
  15 assert lib.assertOneOf "sslLibrary" sslLibrary ["gnutls" "openssl" "no"];
  16
  17 stdenv.mkDerivation rec {
  18   pname = "mpop";
  19   version = "1.4.20";
  20
  21   src = fetchurl {
  22     url = "https://marlam.de/${pname}/releases/${pname}-${version}.tar.xz";
  23     sha256 = "sha256-Ncx94X492spHQ4Y0ZEiPjIKoOsGzdk/d1/QjiBQ1v0s=";
  24   };
  25
  26   nativeBuildInputs = [
  27     pkg-config
  28   ];
  29
  30   buildInputs =
  31     lib.optional stdenv.hostPlatform.isDarwin Security
  32     ++ lib.optional gsaslSupport gsasl
  33     ++ lib.optional idnSupport libidn
  34     ++ lib.optional (sslLibrary == "gnutls") gnutls
  35     ++ lib.optional (sslLibrary == "openssl") openssl;
  36
  37   configureFlags = [
  38     (lib.enableFeature nlsSupport "nls")
  39     (lib.withFeature idnSupport "idn")
  40     (lib.withFeature gsaslSupport "gsasl")
  41     "--with-tls=${sslLibrary}"
  42   ] ++ lib.optional stdenv.hostPlatform.isDarwin "--with-macosx-keyring";
  43
  44   meta = with lib;{
  45     description = "POP3 mail retrieval agent";
  46     homepage = "https://marlam.de/mpop";
  47     license = licenses.gpl3Plus;
  48     platforms = platforms.unix;
  49   };
  50 }