pkgs/applications/networking/sync/rsync/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , updateAutotoolsGnuConfigScriptsHook
   5 , perl
   6 , libiconv
   7 , zlib
   8 , popt
   9 , enableACLs ? lib.meta.availableOn stdenv.hostPlatform acl
  10 , acl
  11 , enableLZ4 ? true
  12 , lz4
  13 , enableOpenSSL ? true
  14 , openssl
  15 , enableXXHash ? true
  16 , xxHash
  17 , enableZstd ? true
  18 , zstd
  19 , nixosTests
  20 }:
  21
  22 stdenv.mkDerivation rec {
  23   pname = "rsync";
  24   version = "3.3.0";
  25
  26   src = fetchurl {
  27     # signed with key 0048 C8B0 26D4 C96F 0E58  9C2F 6C85 9FB1 4B96 A8C5
  28     url = "mirror://samba/rsync/src/rsync-${version}.tar.gz";
  29     hash = "sha256-c5nppnCMMtZ4pypjIZ6W8jvgviM25Q/RNISY0HBB35A=";
  30   };
  31
  32   nativeBuildInputs = [ updateAutotoolsGnuConfigScriptsHook perl ];
  33
  34   patches = [
  35     # https://github.com/WayneD/rsync/pull/558
  36     ./configure.ac-fix-failing-IPv6-check.patch
  37   ];
  38
  39   buildInputs = [ libiconv zlib popt ]
  40     ++ lib.optional enableACLs acl
  41     ++ lib.optional enableZstd zstd
  42     ++ lib.optional enableLZ4 lz4
  43     ++ lib.optional enableOpenSSL openssl
  44     ++ lib.optional enableXXHash xxHash;
  45
  46   configureFlags = [
  47     (lib.enableFeature enableLZ4 "lz4")
  48     (lib.enableFeature enableOpenSSL "openssl")
  49     (lib.enableFeature enableXXHash "xxhash")
  50     (lib.enableFeature enableZstd "zstd")
  51     "--with-nobody-group=nogroup"
  52
  53     # disable the included zlib explicitly as it otherwise still compiles and
  54     # links them even.
  55     "--with-included-zlib=no"
  56   ] ++ lib.optionals (stdenv.hostPlatform.isMusl && stdenv.hostPlatform.isx86_64) [
  57     # fix `multiversioning needs 'ifunc' which is not supported on this target` error
  58     "--disable-roll-simd"
  59   ];
  60
  61   enableParallelBuilding = true;
  62
  63   passthru.tests = { inherit (nixosTests) rsyncd; };
  64
  65   meta = with lib; {
  66     description = "Fast incremental file transfer utility";
  67     homepage = "https://rsync.samba.org/";
  68     license = licenses.gpl3Plus;
  69     mainProgram = "rsync";
  70     maintainers = with lib.maintainers; [ ehmry kampfschlaefer ivan ];
  71     platforms = platforms.unix;
  72   };
  73 }