pkgs/applications/networking/wgnord/default.nix

   1 { bash
   2 , coreutils
   3 , curl
   4 , fetchFromGitHub
   5 , gnugrep
   6 , gnused
   7 , iproute2
   8 , jq
   9 , lib
  10 , resholve
  11 , wireguard-tools
  12 }:
  13
  14 resholve.mkDerivation rec {
  15   pname = "wgnord";
  16   version = "0.2.1";
  17
  18   src = fetchFromGitHub {
  19     owner = "phirecc";
  20     repo = pname;
  21     rev = version;
  22     hash = "sha256-26cfYXtZVQ7kIRxY6oNGCqIjdw/hjwXhVKimVgolLgk=";
  23   };
  24
  25   postPatch = ''
  26     substituteInPlace wgnord \
  27       --replace '$conf_dir/countries.txt' "$out/share/countries.txt" \
  28       --replace '$conf_dir/countries_iso31662.txt' "$out/share/countries_iso31662.txt"
  29   '';
  30
  31   dontBuild = true;
  32
  33   installPhase = ''
  34     install -Dm 755 wgnord -t $out/bin/
  35     install -Dm 644 countries.txt -t $out/share/
  36     install -Dm 644 countries_iso31662.txt -t $out/share/
  37   '';
  38
  39   solutions.default = {
  40     scripts = [ "bin/wgnord" ];
  41     interpreter = "${bash}/bin/sh";
  42     inputs = [
  43       coreutils
  44       curl
  45       gnugrep
  46       gnused
  47       iproute2
  48       jq
  49       wireguard-tools
  50     ];
  51     fix.aliases = true; # curl command in an alias
  52     execer = [
  53       "cannot:${iproute2}/bin/ip"
  54       "cannot:${wireguard-tools}/bin/wg-quick"
  55     ];
  56   };
  57
  58   meta = with lib; {
  59     description = "NordVPN Wireguard (NordLynx) client in POSIX shell";
  60     homepage = "https://github.com/phirecc/wgnord";
  61     changelog = "https://github.com/phirecc/wgnord/releases/tag/v${version}";
  62     maintainers = with lib.maintainers; [ urandom ];
  63     license = licenses.mit;
  64     mainProgram = "wgnord";
  65     platforms = platforms.linux;
  66   };
  67 }