pkgs/applications/science/biology/iv/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , neuron-version
   5 , libX11
   6 , libXext
   7 , patchelf
   8 }:
   9
  10 stdenv.mkDerivation rec {
  11   pname = "iv";
  12   version = "19";
  13
  14   src = fetchurl {
  15     url = "https://www.neuron.yale.edu/ftp/neuron/versions/v${neuron-version}/iv-${version}.tar.gz";
  16     sha256 = "07a3g8zzay4h0bls7fh89dd0phn7s34c2g15pij6dsnwpmjg06yx";
  17   };
  18
  19   nativeBuildInputs = [ patchelf ];
  20   buildInputs = [ libXext ];
  21   propagatedBuildInputs = [ libX11 ];
  22
  23   hardeningDisable = [ "format" ];
  24
  25   postInstall = ''
  26     for dir in $out/*; do # */
  27       if [ -d $dir/lib ]; then
  28         mv $dir/* $out # */
  29         rmdir $dir
  30         break
  31       fi
  32     done
  33   '' + lib.optionalString stdenv.hostPlatform.isLinux ''
  34     patchelf --add-needed ${libX11}/lib/libX11.so $out/lib/libIVhines.so
  35   '';
  36
  37   meta = with lib; {
  38     description = "InterViews graphical library for Neuron";
  39     license = licenses.bsd3;
  40     homepage = "http://www.neuron.yale.edu/neuron";
  41     platforms = platforms.all;
  42   };
  43 }