pkgs/applications/science/chemistry/autodock-vina/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , boost
   5 , glibc
   6 }:
   7 let
   8   boost' = boost.override {
   9     enableShared = false;
  10   };
  11 in
  12 stdenv.mkDerivation (finalAttrs: {
  13   pname = "autodock-vina";
  14   version = "1.2.5";
  15
  16   src = fetchFromGitHub {
  17     owner = "ccsb-scripps";
  18     repo = "autodock-vina";
  19     rev = "refs/tags/v${finalAttrs.version}";
  20     hash = "sha256-yguUMEX0tn75wKrPKyqlCYbBFaEwC5b1s3k9xept1Fw=";
  21   };
  22
  23   sourceRoot = "${finalAttrs.src.name}/build/${
  24     if stdenv.hostPlatform.isDarwin then "mac"
  25     else "linux"
  26   }/release";
  27
  28   buildInputs = [
  29     boost'
  30   ] ++ lib.optionals stdenv.hostPlatform.isLinux [
  31     glibc.static
  32   ];
  33
  34   makeFlags = [
  35     "GPP=${stdenv.cc.targetPrefix}c++"
  36     "BASE=${boost'}"
  37     "BOOST_INCLUDE=${lib.getDev boost'}/include"
  38   ];
  39
  40   installPhase = ''
  41     runHook preInstall
  42
  43     install -Dm755 vina vina_split -t $out/bin/
  44
  45     runHook postInstall
  46   '';
  47
  48   meta = with lib; {
  49     description = "One of the fastest and most widely used open-source docking engines";
  50     homepage = "https://vina.scripps.edu/";
  51     changelog = "https://github.com/ccsb-scripps/AutoDock-Vina/releases/tag/v${finalAttrs.version}";
  52     license = licenses.asl20;
  53     maintainers = with maintainers; [ natsukium ];
  54     platforms = platforms.unix;
  55     mainProgram = "vina";
  56   };
  57 })