pkgs/desktops/gnustep/base/default.nix

   1 { lib
   2 , stdenv
   3 , aspell
   4 , audiofile
   5 , make
   6 , wrapGNUstepAppsHook
   7 , cups
   8 , fetchzip
   9 , fetchpatch
  10 , gmp
  11 , gnutls
  12 , libffi
  13 , binutils-unwrapped
  14 , libjpeg
  15 , libtiff
  16 , libpng
  17 , giflib
  18 , libxml2
  19 , libxslt
  20 , libiconv
  21 , libobjc
  22 , libgcrypt
  23 , icu
  24 , pkg-config
  25 , portaudio
  26 , libiberty
  27 }:
  28
  29 stdenv.mkDerivation (finalAttrs: {
  30   pname = "gnustep-base";
  31   version = "1.29.0";
  32   src = fetchzip {
  33     url = "ftp://ftp.gnustep.org/pub/gnustep/core/gnustep-base-${finalAttrs.version}.tar.gz";
  34     hash = "sha256-4fjdsLBsYEDxLOFrq17dKii2sLKvOaFCu0cw3qQtM5U=";
  35   };
  36   outputs = [ "out" "dev" "lib" ];
  37   nativeBuildInputs = [ pkg-config make wrapGNUstepAppsHook ];
  38   propagatedBuildInputs = [
  39     aspell audiofile
  40     cups
  41     gmp gnutls
  42     libffi binutils-unwrapped
  43     libjpeg libtiff libpng giflib
  44     libxml2 libxslt libiconv
  45     libobjc libgcrypt
  46     icu
  47     portaudio
  48     libiberty
  49   ];
  50   patches = [
  51     ./fixup-paths.patch
  52     # https://github.com/gnustep/libs-base/issues/212 / https://www.sogo.nu/bugs/view.php?id=5416#c15585
  53     (fetchpatch {
  54       url = "https://github.com/gnustep/libs-base/commit/bd5f2909e6edc8012a0a6e44ea1402dfbe1353a4.patch";
  55       revert = true;
  56       sha256 = "02awigkbhqa60hfhqfh2wjsa960y3q6557qck1k2l231piz2xasa";
  57     })
  58     # https://github.com/gnustep/libs-base/issues/294
  59     (fetchpatch {
  60       url = "https://github.com/gnustep/libs-base/commit/37913d006d96a6bdcb963f4ca4889888dcce6094.patch";
  61       sha256 = "PyOmzRIirSKG5SQY+UwD6moCidPb8PXCx3aFgfwxsXE=";
  62     })
  63     # https://github.com/gnustep/libs-base/pull/334
  64     (fetchpatch {
  65       url = "https://github.com/gnustep/libs-base/commit/b4feee311f2beaf499a5742967213f523de30f16.patch";
  66       excludes = [ "ChangeLog" ];
  67       hash = "sha256-r0qpxjpEM6y+F/gju6JhpDNxnFJNHFG/mt3NmC1hWrs=";
  68     })
  69   ];
  70
  71   meta = {
  72     changelog = "https://github.com/gnustep/libs-base/releases/tag/base-${builtins.replaceStrings [ "." ] [ "_" ] finalAttrs.version}";
  73     description = "Implementation of AppKit and Foundation libraries of OPENSTEP and Cocoa";
  74     homepage = "https://gnustep.github.io/";
  75     license = lib.licenses.lgpl2Plus;
  76     maintainers = with lib.maintainers; [ ashalkhakov matthewbauer dblsaiko ];
  77     platforms = lib.platforms.linux;
  78   };
  79 })