pkgs/development/libraries/gcr/4.nix

   1 { stdenv
   2 , lib
   3 , fetchurl
   4 , pkg-config
   5 , meson
   6 , ninja
   7 , gettext
   8 , gnupg
   9 , p11-kit
  10 , glib
  11 , libgcrypt
  12 , libtasn1
  13 , gtk4
  14 , pango
  15 , libsecret
  16 , openssh
  17 , systemd
  18 , gobject-introspection
  19 , wrapGAppsHook4
  20 , vala
  21 , gi-docgen
  22 , gnome
  23 , python3
  24 , shared-mime-info
  25 , systemdSupport ? lib.meta.availableOn stdenv.hostPlatform systemd
  26 }:
  27
  28 stdenv.mkDerivation rec {
  29   pname = "gcr";
  30   version = "4.3.0";
  31
  32   outputs = [ "out" "bin" "dev" "devdoc" ];
  33
  34   src = fetchurl {
  35     url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  36     hash = "sha256-w+6HKOQ2SwOX9DX6IPkvkBqxOdKyZPTgWdZ7PA9DzTY=";
  37   };
  38
  39   strictDeps = true;
  40
  41   nativeBuildInputs = [
  42     pkg-config
  43     meson
  44     ninja
  45     gettext
  46     gobject-introspection
  47     gi-docgen
  48     wrapGAppsHook4
  49     vala
  50     gi-docgen
  51     shared-mime-info
  52   ];
  53
  54   buildInputs = [
  55     libgcrypt
  56     libtasn1
  57     pango
  58     libsecret
  59     openssh
  60     gtk4
  61   ] ++ lib.optionals systemdSupport [
  62     systemd
  63   ];
  64
  65   propagatedBuildInputs = [
  66     glib
  67     p11-kit
  68   ];
  69
  70   nativeCheckInputs = [
  71     python3
  72   ];
  73
  74   mesonFlags = [
  75     # We are still using ssh-agent from gnome-keyring.
  76     # https://github.com/NixOS/nixpkgs/issues/140824
  77     "-Dssh_agent=false"
  78     "-Dgpg_path=${lib.getBin gnupg}/bin/gpg"
  79     (lib.mesonEnable "systemd" systemdSupport)
  80   ];
  81
  82   doCheck = false; # fails 21 out of 603 tests, needs dbus daemon
  83
  84   PKG_CONFIG_SYSTEMD_SYSTEMDUSERUNITDIR = "${placeholder "out"}/lib/systemd/user";
  85
  86   postPatch = ''
  87     patchShebangs gcr/fixtures/
  88   '';
  89
  90   postFixup = ''
  91     # Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.
  92     moveToOutput "share/doc" "$devdoc"
  93   '';
  94
  95   passthru = {
  96     updateScript = gnome.updateScript {
  97       attrPath = "gcr_4";
  98       packageName = pname;
  99     };
 100   };
 101
 102   meta = with lib; {
 103     platforms = platforms.unix;
 104     maintainers = teams.gnome.members;
 105     description = "GNOME crypto services (daemon and tools)";
 106     mainProgram = "gcr-viewer-gtk4";
 107     homepage = "https://gitlab.gnome.org/GNOME/gcr";
 108     license = licenses.lgpl2Plus;
 109
 110     longDescription = ''
 111       GCR is a library for displaying certificates, and crypto UI, accessing
 112       key stores. It also provides the viewer for crypto files on the GNOME
 113       desktop.
 114
 115       GCK is a library for accessing PKCS#11 modules like smart cards, in a
 116       (G)object oriented way.
 117     '';
 118   };
 119 }