pkgs/development/libraries/geos/3.11.nix

   1 { lib
   2 , stdenv
   3 , callPackage
   4 , fetchpatch
   5 , fetchurl
   6 , testers
   7
   8 , cmake
   9 }:
  10
  11 stdenv.mkDerivation (finalAttrs: {
  12   pname = "geos";
  13   version = "3.11.4";
  14
  15   src = fetchurl {
  16     url = "https://download.osgeo.org/geos/geos-${finalAttrs.version}.tar.bz2";
  17     hash = "sha256-NkyIzPw4qlDPZccA57KuRwbtEDMmEoST2/dQx40TbSw=";
  18   };
  19
  20   patches = [
  21     # Pull upstream fix of `gcc-13` build failure:
  22     #   https://github.com/libgeos/geos/pull/805
  23     (fetchpatch {
  24       name = "gcc-13.patch";
  25       url = "https://github.com/libgeos/geos/commit/bea3188be44075034fd349f5bb117c943bdb7fb1.patch";
  26       hash = "sha256-dQT3Hf9YJchgjon/r46TLIXXbE6C0ZnewyvfYJea4jM=";
  27     })
  28   ];
  29
  30   nativeBuildInputs = [ cmake ];
  31
  32   # https://github.com/libgeos/geos/issues/930
  33   cmakeFlags = lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64) [
  34     "-DCMAKE_CTEST_ARGUMENTS=--exclude-regex;unit-geom-Envelope"
  35   ];
  36
  37   doCheck = true;
  38
  39   passthru.tests = {
  40     pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
  41     geos = callPackage ./tests.nix { geos = finalAttrs.finalPackage; };
  42   };
  43
  44   meta = with lib; {
  45     description = "C/C++ library for computational geometry with a focus on algorithms used in geographic information systems (GIS) software";
  46     homepage = "https://libgeos.org";
  47     license = licenses.lgpl21Only;
  48     maintainers = teams.geospatial.members;
  49     pkgConfigModules = [ "geos" ];
  50     mainProgram = "geosop";
  51   };
  52 })