pkgs/development/libraries/glew/1.10.nix

   1 { lib, stdenv, fetchurl, libGLU, libXmu, libXi, libXext
   2 , AGL, OpenGL
   3 , testers
   4 , mesa
   5 }:
   6
   7 stdenv.mkDerivation (finalAttrs: {
   8   pname = "glew";
   9   version = "1.10.0";
  10
  11   src = fetchurl {
  12     url = "mirror://sourceforge/glew/glew-${finalAttrs.version}.tgz";
  13     sha256 = "01zki46dr5khzlyywr3cg615bcal32dazfazkf360s1znqh17i4r";
  14   };
  15
  16   buildInputs = if stdenv.hostPlatform.isDarwin then [ AGL ] else [ libXmu libXi libXext ];
  17   propagatedBuildInputs = if stdenv.hostPlatform.isDarwin then [ OpenGL ] else [ libGLU ]; # GL/glew.h includes GL/glu.h
  18
  19   outputs = [ "out" "dev" ];
  20
  21   patchPhase = ''
  22     sed -i 's|lib64|lib|' config/Makefile.linux
  23     ${lib.optionalString (stdenv.hostPlatform != stdenv.buildPlatform) ''
  24     sed -i -e 's/\(INSTALL.*\)-s/\1/' Makefile
  25     ''}
  26   '';
  27
  28   buildFlags = [ "all" ];
  29   installFlags = [ "install.all" ];
  30
  31   preInstall = ''
  32     export GLEW_DEST="$out"
  33   '';
  34
  35   postInstall = ''
  36     mkdir -pv $out/share/doc/glew
  37     mkdir -p $dev/lib/pkgconfig
  38     cp glew*.pc $dev/lib/pkgconfig
  39     cp -r README.txt LICENSE.txt doc $out/share/doc/glew
  40   '';
  41
  42   makeFlags = [
  43     "SYSTEM=${if stdenv.hostPlatform.isMinGW then "mingw" else stdenv.hostPlatform.parsed.kernel.name}"
  44     "CC:=$(CC)"
  45     "LD:=$(CC)"
  46   ];
  47
  48   passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
  49
  50   meta = with lib; {
  51     description = "OpenGL extension loading library for C(++)";
  52     homepage = "https://glew.sourceforge.net/";
  53     license = licenses.free; # different files under different licenses
  54       #["BSD" "GLX" "SGI-B" "GPL2"]
  55     pkgConfigModules = [ "glew" ];
  56     inherit (mesa.meta) platforms;
  57   };
  58 })