pkgs/games/stuntrally/default.nix

   1 { lib
   2 , fetchFromGitHub
   3 , stdenv
   4 , cmake
   5 , boost
   6 , ogre_13
   7 , mygui
   8 , ois
   9 , SDL2
  10 , libvorbis
  11 , pkg-config
  12 , makeWrapper
  13 , enet
  14 , libXcursor
  15 , bullet
  16 , openal
  17 , tinyxml
  18 , tinyxml-2
  19 }:
  20
  21 let
  22   stuntrally_ogre = ogre_13.overrideAttrs (old: {
  23     cmakeFlags = old.cmakeFlags ++ [
  24       "-DOGRE_NODELESS_POSITIONING=ON"
  25       "-DOGRE_RESOURCEMANAGER_STRICT=0"
  26     ];
  27   });
  28   stuntrally_mygui = mygui.override {
  29     withOgre = true;
  30     ogre = stuntrally_ogre;
  31   };
  32 in
  33
  34 stdenv.mkDerivation rec {
  35   pname = "stuntrally";
  36   version = "2.7";
  37
  38   src = fetchFromGitHub {
  39     owner = "stuntrally";
  40     repo = "stuntrally";
  41     rev = version;
  42     hash = "sha256-0Eh9ilIHSh/Uz8TuPnXxLQfy7KF7qqNXUgBXQUCz9ys=";
  43   };
  44   tracks = fetchFromGitHub {
  45     owner = "stuntrally";
  46     repo = "tracks";
  47     rev = version;
  48     hash = "sha256-fglm1FetFGHM/qGTtpxDb8+k2iAREn5DQR5GPujuLms=";
  49   };
  50
  51   postPatch = ''
  52     substituteInPlace config/*-default.cfg \
  53       --replace "screenshot_png = off" "screenshot_png = on"
  54     substituteInPlace source/*/BaseApp_Create.cpp \
  55       --replace "Codec_FreeImage" "Codec_STBI"
  56   '';
  57
  58   preConfigure = ''
  59     rmdir data/tracks
  60     ln -s ${tracks}/ data/tracks
  61   '';
  62
  63   nativeBuildInputs = [ cmake pkg-config makeWrapper ];
  64   buildInputs = [
  65     boost
  66     stuntrally_ogre
  67     stuntrally_mygui
  68     ois
  69     SDL2
  70     libvorbis
  71     enet
  72     libXcursor
  73     bullet
  74     openal
  75     tinyxml
  76     tinyxml-2
  77   ];
  78
  79   meta = with lib; {
  80     description = "Stunt Rally game with Track Editor, based on VDrift and OGRE";
  81     homepage = "http://stuntrally.tuxfamily.org/";
  82     license = licenses.gpl3Plus;
  83     maintainers = with maintainers; [ pSub ];
  84     platforms = platforms.linux;
  85   };
  86 }