pkgs/os-specific/linux/rtl8852bu/default.nix

   1 { lib, stdenv, fetchFromGitHub, kernel, bc, nukeReferences }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "rtl8852bu";
   5   version = "${kernel.version}-unstable-2024-05-25";
   6
   7   src = fetchFromGitHub {
   8     owner = "morrownr";
   9     repo = pname;
  10     rev = "1acc7aa085bffec21a91fdc9e293378e06bf25e7";
  11     hash = "sha256-22vzAdzzM5YnfU8kRWSK3HXxw6BA4FOWXLdWEb7T5IE=";
  12   };
  13
  14   nativeBuildInputs = [ bc nukeReferences ] ++ kernel.moduleBuildDependencies;
  15   hardeningDisable = [ "pic" "format" ];
  16
  17   postPatch = ''
  18     substituteInPlace ./Makefile \
  19       --replace-fail /sbin/depmod \# \
  20       --replace-fail '$(MODDESTDIR)' "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
  21     substituteInPlace ./platform/i386_pc.mk \
  22       --replace-fail /lib/modules "${kernel.dev}/lib/modules"
  23   '';
  24
  25   makeFlags = [
  26     "ARCH=${stdenv.hostPlatform.linuxArch}"
  27     ("CONFIG_PLATFORM_I386_PC=" + (if stdenv.hostPlatform.isx86 then "y" else "n"))
  28     ("CONFIG_PLATFORM_ARM_RPI=" + (if stdenv.hostPlatform.isAarch then "y" else "n"))
  29   ] ++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
  30     "CROSS_COMPILE=${stdenv.cc.targetPrefix}"
  31   ];
  32
  33   preInstall = ''
  34     mkdir -p "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
  35     mkdir -p "$out/usr/lib/systemd/system-sleep"
  36   '';
  37
  38   postInstall = ''
  39     nuke-refs $out/lib/modules/*/kernel/net/wireless/*.ko
  40   '';
  41
  42   enableParallelBuilding = true;
  43
  44   meta = with lib; {
  45     description = "Driver for Realtek rtl8852bu and rtl8832bu chipsets, provides the 8852bu mod";
  46     homepage = "https://github.com/morrownr/rtl8852bu";
  47     license = licenses.gpl2Only;
  48     platforms = platforms.linux;
  49     maintainers = with maintainers; [ lonyelon ];
  50   };
  51 }