pkgs/tools/archivers/zpaq/zpaqd.nix

   1 { lib, stdenv, fetchurl, unzip }:
   2
   3 let
   4   compileFlags = lib.concatStringsSep " " ([ "-O3" "-DNDEBUG" ]
   5     ++ lib.optional (stdenv.hostPlatform.isUnix) "-Dunix -pthread"
   6     ++ lib.optional (!stdenv.hostPlatform.isx86) "-DNOJIT");
   7 in
   8 stdenv.mkDerivation rec {
   9   pname = "zpaqd";
  10   version = "715";
  11
  12   src = fetchurl {
  13     url = "http://mattmahoney.net/dc/zpaqd${version}.zip";
  14     sha256 = "sha256-Mx87Zt0AASk0ZZCjyTzYbhlYJAXBlb59OpUWsqynyCA=";
  15   };
  16
  17   sourceRoot = ".";
  18
  19   nativeBuildInputs = [ unzip ];
  20
  21   buildPhase = ''
  22     $CXX ${compileFlags} -fPIC --shared libzpaq.cpp -o libzpaq.so
  23     $CXX ${compileFlags} -L. -L"$out/lib" -lzpaq zpaqd.cpp -o zpaqd
  24   '';
  25
  26   installPhase = ''
  27     mkdir -p "$out"/{bin,include,lib,share/doc/zpaq}
  28     cp libzpaq.so "$out/lib"
  29     cp zpaqd "$out/bin"
  30     cp libzpaq.h "$out/include"
  31     cp readme_zpaqd.txt "$out/share/doc/zpaq"
  32   '';
  33
  34   meta = with lib; {
  35     description = "ZPAQ archive (de)compressor and algorithm development tool";
  36     mainProgram = "zpaqd";
  37     license = licenses.gpl3Plus;
  38     maintainers = with maintainers; [ raskin ];
  39     platforms = platforms.linux;
  40   };
  41 }