pkgs/tools/misc/pandoc-acro/default.nix

   1 { buildPythonApplication
   2 , fetchPypi
   3 , pandocfilters
   4 , panflute
   5 , lib
   6 , pandoc
   7 , pandoc-acro
   8 , texliveTeTeX
   9 , runCommand
  10 }:
  11
  12 let
  13   pname = "pandoc-acro";
  14   version = "0.10.1";
  15
  16   src = fetchPypi {
  17     inherit pname version;
  18     hash = "sha256-JMfSQXX+BCGdFQYPFB+r08WRnhT3aXfnBNINROxCUA0=";
  19   };
  20 in
  21 buildPythonApplication {
  22   inherit pname version src;
  23
  24   propagatedBuildInputs = [
  25     pandocfilters
  26     panflute
  27   ];
  28
  29   # Something in the tests does not typecheck, but the tool works well.
  30   doCheck = false;
  31
  32   passthru.tests.example-doc =
  33     let
  34         env = {
  35           nativeBuildInputs = [
  36             pandoc
  37             pandoc-acro
  38             (texliveTeTeX.withPackages (ps: with ps; [ acro translations ]))
  39           ];
  40         };
  41       in
  42       runCommand "pandoc-acro-example-docs" env ''
  43         set -euo pipefail
  44         exampleFile="${pname}-${version}/tests/example.md"
  45         metadataFile="${pname}-${version}/tests/metadata.yaml"
  46         tar --extract "--file=${src}" "$exampleFile" "$metadataFile"
  47         mkdir $out
  48
  49         pandoc -F pandoc-acro "$exampleFile" "--metadata-file=$metadataFile" \
  50           -T pdf -o $out/example.pdf
  51         pandoc -F pandoc-acro  "$exampleFile" "--metadata-file=$metadataFile" \
  52           -T txt -o $out/example.txt
  53
  54         ! grep -q "\+afaik" $out/example.txt
  55       '';
  56
  57   meta = with lib; {
  58     homepage = "https://pypi.org/project/pandoc-acro/";
  59     description = "Pandoc filter which manages acronyms in Pandoc flavored Markdown sources";
  60     license = licenses.bsd2;
  61     maintainers = with maintainers; [ tfc ];
  62     mainProgram = "pandoc-acro";
  63   };
  64 }