pkgs/servers/mail/mailman/default.nix

   1 { newScope, lib, python3 }:
   2
   3 let
   4   self = lib.makeExtensible (self: let inherit (self) callPackage; in {
   5     callPackage = newScope self;
   6
   7     python3 = callPackage ./python.nix { inherit python3; };
   8
   9     hyperkitty = callPackage ./hyperkitty.nix { };
  10
  11     mailman = callPackage ./package.nix { };
  12
  13     mailman-hyperkitty = callPackage ./mailman-hyperkitty.nix { };
  14
  15     postorius = callPackage ./postorius.nix { };
  16
  17     web = callPackage ./web.nix { };
  18
  19     buildEnvs = { web ? self.web
  20                 , mailman ? self.mailman
  21                 , mailman-hyperkitty ? self.mailman-hyperkitty
  22                 , withHyperkitty ? false
  23                 , withLDAP ? false
  24                 }:
  25       {
  26         mailmanEnv = self.python3.withPackages
  27           (ps: [ mailman ps.psycopg2 ]
  28             ++ lib.optional withHyperkitty mailman-hyperkitty
  29             ++ lib.optionals withLDAP [ ps.python-ldap ps.django-auth-ldap ]);
  30         webEnv = self.python3.withPackages
  31           (ps: [ web ps.psycopg2 ] ++ lib.optionals withLDAP [ ps.python-ldap ps.django-auth-ldap ]);
  32       };
  33   });
  34
  35 in self