pkgs/servers/monitoring/grafana-agent/default.nix

   1 { lib
   2 , buildGoModule
   3 , fetchFromGitHub
   4 , fetchYarnDeps
   5 , fixup-yarn-lock
   6 , grafana-agent
   7 , nix-update-script
   8 , nixosTests
   9 , nodejs
  10 , stdenv
  11 , systemd
  12 , testers
  13 , yarn
  14 }:
  15
  16 buildGoModule rec {
  17   pname = "grafana-agent";
  18   version = "0.41.1";
  19
  20   src = fetchFromGitHub {
  21     owner = "grafana";
  22     repo = "agent";
  23     rev = "v${version}";
  24     hash = "sha256-A/h8Mwtor4VUT7e7TsNiE/0OOXCSq38GAf9j7c8ZDKk=";
  25   };
  26
  27   vendorHash = "sha256-W29GZoZfgjdSwGiFz4udGA9gXgmM0xIDEGld7ZE1ycQ=";
  28   proxyVendor = true; # darwin/linux hash mismatch
  29
  30   frontendYarnOfflineCache = fetchYarnDeps {
  31     yarnLock = src + "/internal/web/ui/yarn.lock";
  32     hash = "sha256-WqbIg18qUNcs9O2wh7DAzwXKb60iEuPL8zFCIgScqI0=";
  33   };
  34
  35   ldflags = let
  36     prefix = "github.com/grafana/agent/internal/build";
  37   in [
  38     "-s" "-w"
  39     # https://github.com/grafana/agent/blob/v0.41.0/Makefile#L132-L137
  40     "-X ${prefix}.Version=${version}"
  41     "-X ${prefix}.Branch=v${version}"
  42     "-X ${prefix}.Revision=v${version}"
  43     "-X ${prefix}.BuildUser=nix"
  44     "-X ${prefix}.BuildDate=1980-01-01T00:00:00Z"
  45   ];
  46
  47   nativeBuildInputs = [ fixup-yarn-lock nodejs yarn ];
  48
  49   tags = [
  50     "builtinassets"
  51     "nonetwork"
  52     "nodocker"
  53     "promtail_journal_enabled"
  54   ];
  55
  56   subPackages = [
  57     "cmd/grafana-agent"
  58     "cmd/grafana-agentctl"
  59     "internal/web/ui"
  60   ];
  61
  62   preBuild = ''
  63     export HOME="$TMPDIR"
  64
  65     pushd internal/web/ui
  66     fixup-yarn-lock yarn.lock
  67     yarn config --offline set yarn-offline-mirror $frontendYarnOfflineCache
  68     yarn install --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive
  69     patchShebangs node_modules
  70     yarn --offline run build
  71     popd
  72   '';
  73
  74   # do not pass preBuild to go-modules.drv, as it would otherwise fail to build.
  75   # but even if it would work, it simply isn't needed in that scope.
  76   overrideModAttrs = (_: {
  77     preBuild = null;
  78   });
  79
  80   # uses go-systemd, which uses libsystemd headers
  81   # https://github.com/coreos/go-systemd/issues/351
  82   env.NIX_CFLAGS_COMPILE = toString (lib.optionals stdenv.isLinux [ "-I${lib.getDev systemd}/include" ]);
  83
  84   # go-systemd uses libsystemd under the hood, which does dlopen(libsystemd) at
  85   # runtime.
  86   # Add to RUNPATH so it can be found.
  87   postFixup = lib.optionalString stdenv.isLinux ''
  88     patchelf \
  89       --set-rpath "${lib.makeLibraryPath [ (lib.getLib systemd) ]}:$(patchelf --print-rpath $out/bin/grafana-agent)" \
  90       $out/bin/grafana-agent
  91   '';
  92
  93   passthru = {
  94     tests = {
  95       inherit (nixosTests) grafana-agent;
  96       version = testers.testVersion {
  97         inherit version;
  98         command = "${lib.getExe grafana-agent} --version";
  99         package = grafana-agent;
 100       };
 101     };
 102     updateScript = nix-update-script { };
 103     # alias for nix-update to be able to find and update this attribute
 104     offlineCache = frontendYarnOfflineCache;
 105   };
 106
 107   meta = {
 108     description = "Lightweight subset of Prometheus and more, optimized for Grafana Cloud";
 109     license = lib.licenses.asl20;
 110     homepage = "https://grafana.com/products/cloud";
 111     changelog = "https://github.com/grafana/agent/blob/${src.rev}/CHANGELOG.md";
 112     maintainers = with lib.maintainers; [ flokli emilylange ];
 113     mainProgram = "grafana-agent";
 114   };
 115 }