pkgs/servers/nosql/influxdb/default.nix

   1 { lib, buildGoModule, fetchFromGitHub, stdenv, pkg-config, rustPlatform, libiconv, fetchpatch, nixosTests }:
   2
   3 let
   4   libflux_version = "0.194.5";
   5
   6   # This is copied from influxdb2 with the required flux version
   7   flux = rustPlatform.buildRustPackage rec {
   8     pname = "libflux";
   9     version = "v${libflux_version}";
  10     src = fetchFromGitHub {
  11       owner = "influxdata";
  12       repo = "flux";
  13       rev = "v${libflux_version}";
  14       hash = "sha256-XHT/+JMu5q1cPjZT2x/OKEPgxFJcnjrQKqn8w9/Mb3s=";
  15     };
  16     patches = [
  17       # Fix build on Rust 1.78 (included after v0.195.0)
  18       (fetchpatch {
  19         name = "fix-build-on-rust-1.78.patch";
  20         url = "https://github.com/influxdata/flux/commit/68c831c40b396f0274f6a9f97d77707c39970b02.patch";
  21         stripLen = 2;
  22         extraPrefix = "";
  23         excludes = [ ];
  24         hash = "sha256-6LOTgbOCfETNTmshyXgtDZf9y4t/2iqRuVPkz9dYPHc=";
  25       })
  26       ../influxdb2/fix-unsigned-char.patch
  27     ];
  28     sourceRoot = "${src.name}/libflux";
  29     cargoHash = "sha256-O+t4f4P5291BuyARH6Xf3LejMFEQEBv+qKtyjHRhclA=";
  30     nativeBuildInputs = [ rustPlatform.bindgenHook ];
  31     buildInputs = lib.optional stdenv.isDarwin libiconv;
  32     pkgcfg = ''
  33       Name: flux
  34       Version: ${libflux_version}
  35       Description: Library for the InfluxData Flux engine
  36       Cflags: -I/out/include
  37       Libs: -L/out/lib -lflux -lpthread
  38     '';
  39     passAsFile = [ "pkgcfg" ];
  40     postInstall = ''
  41       mkdir -p $out/include $out/pkgconfig
  42       cp -r $NIX_BUILD_TOP/source/libflux/include/influxdata $out/include
  43       substitute $pkgcfgPath $out/pkgconfig/flux.pc \
  44         --replace /out $out
  45     '' + lib.optionalString stdenv.isDarwin ''
  46       install_name_tool -id $out/lib/libflux.dylib $out/lib/libflux.dylib
  47     '';
  48   };
  49 in
  50 buildGoModule rec {
  51   pname = "influxdb";
  52   version = "1.10.7";
  53
  54   src = fetchFromGitHub {
  55     owner = "influxdata";
  56     repo = pname;
  57     rev = "v${version}";
  58     hash = "sha256-Aibu3yG/D1501Hr2F2qsGvjig14tbEAI+MBfqbxlpg8=";
  59   };
  60
  61   vendorHash = "sha256-AA6uj7PgXjC+IK2ZSwRnYpHS4MFScOROO1BpP+s33IU=";
  62
  63   nativeBuildInputs = [ pkg-config ];
  64
  65   PKG_CONFIG_PATH = "${flux}/pkgconfig";
  66
  67   # Check that libflux is at the right version
  68   preBuild = ''
  69     flux_ver=$(grep github.com/influxdata/flux go.mod | awk '{print $2}')
  70     if [ "$flux_ver" != "v${libflux_version}" ]; then
  71       echo "go.mod wants libflux $flux_ver, but nix derivation provides ${libflux_version}"
  72       exit 1
  73     fi
  74   '';
  75
  76   doCheck = false;
  77
  78   ldflags = [ "-s" "-w" "-X main.version=${version}" ];
  79
  80   excludedPackages = "test";
  81
  82   passthru.tests = { inherit (nixosTests) influxdb; };
  83
  84   meta = with lib; {
  85     description = "Open-source distributed time series database";
  86     license = licenses.mit;
  87     homepage = "https://influxdata.com/";
  88     maintainers = with maintainers; [ offline zimbatm ];
  89   };
  90 }