pkgs/servers/psitransfer/default.nix

   1 { lib
   2 , buildNpmPackage
   3 , fetchFromGitHub
   4 , pkg-config
   5 , vips
   6 }:
   7
   8 let
   9   pname = "psitransfer";
  10   version = "2.2.0";
  11   src = fetchFromGitHub {
  12     owner = "psi-4ward";
  13     repo = "psitransfer";
  14     rev = "v${version}";
  15     hash = "sha256-5o4QliAXgSZekIy0CNWfEuOxNl0uetL8C8RKUJ8HsNA=";
  16   };
  17   app = buildNpmPackage {
  18     pname = "${pname}-app";
  19     inherit version src;
  20
  21     npmDepsHash = "sha256-q7E+osWIf6VZ3JvxCXoZYeF28aMgmKP6EzQkksUUjeY=";
  22
  23     postPatch = ''
  24       # https://github.com/psi-4ward/psitransfer/pull/284
  25       touch public/app/.npmignore
  26       cd app
  27     '';
  28
  29     installPhase = ''
  30       cp -r ../public/app $out
  31     '';
  32   };
  33 in buildNpmPackage {
  34   inherit pname version src;
  35
  36   npmDepsHash = "sha256-EW/Fej58LE/nbJomPtWvEjDveAUdo0jIWwC+ziN0gy0=";
  37
  38   nativeBuildInputs = [ pkg-config ];
  39   buildInputs = [
  40     vips  # for 'sharp' dependency
  41   ];
  42
  43   postPatch = ''
  44     rm -r public/app
  45     cp -r ${app} public/app
  46   '';
  47
  48   dontBuild = true;
  49
  50   meta = {
  51     homepage = "https://github.com/psi-4ward/psitransfer";
  52     description = "Simple open source self-hosted file sharing solution";
  53     license = lib.licenses.bsd2;
  54     maintainers = with lib.maintainers; [ hyshka ];
  55     mainProgram = "psitransfer";
  56   };
  57 }