pkgs/servers/web-apps/pict-rs/0.3.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitea
   4 , rustPlatform
   5 , makeWrapper
   6 , protobuf
   7 , Security
   8 , imagemagick
   9 , ffmpeg
  10 , exiftool
  11 , nixosTests
  12 }:
  13
  14 rustPlatform.buildRustPackage rec {
  15   pname = "pict-rs";
  16   version = "0.3.3";
  17
  18   src = fetchFromGitea {
  19     domain = "git.asonix.dog";
  20     owner = "asonix";
  21     repo = pname;
  22     rev = "v${version}";
  23     sha256 = "mEZBFDR+/aMRFw54Yq+f1gyEz8H+5IggNCpzv3UdDFg=";
  24   };
  25
  26   cargoLock = {
  27     lockFile = ./Cargo-0.3.lock;
  28     outputHashes = {
  29       "aws-creds-0.29.1" = "bwDFmDPThMLrpaB7cAj/2/vJKhbX6/DqgcIRBVKSZhg=";
  30     };
  31   };
  32
  33   # needed for internal protobuf c wrapper library
  34   PROTOC = "${protobuf}/bin/protoc";
  35   PROTOC_INCLUDE = "${protobuf}/include";
  36
  37   nativeBuildInputs = [ makeWrapper ];
  38   buildInputs = lib.optionals stdenv.isDarwin [ Security ];
  39
  40   postInstall = ''
  41     wrapProgram "$out/bin/pict-rs" \
  42         --prefix PATH : "${lib.makeBinPath [ imagemagick ffmpeg exiftool ]}"
  43   '';
  44
  45   passthru.tests = { inherit (nixosTests) pict-rs; };
  46
  47   meta = with lib; {
  48     description = "Simple image hosting service";
  49     mainProgram = "pict-rs";
  50     homepage = "https://git.asonix.dog/asonix/pict-rs";
  51     license = with licenses; [ agpl3Plus ];
  52     maintainers = with maintainers; [ happysalada ];
  53   };
  54 }