pkgs/test/dotnet/project-references/default.nix

   1 # Tests the `projectReferences = [ ... ];` feature of buildDotnetModule.
   2 # The `library` derivation exposes a .nupkg, which is then consumed by the `application` derivation.
   3 # https://nixos.org/manual/nixpkgs/unstable/index.html#packaging-a-dotnet-application
   4
   5 { lib
   6 , dotnet-sdk
   7 , buildPackages # buildDotnetModule
   8 , runCommand
   9 }:
  10
  11 let
  12   inherit (buildPackages) buildDotnetModule;
  13
  14   nugetDeps = ./nuget-deps.nix;
  15
  16   # Specify the TargetFramework via an environment variable so that we don't
  17   # have to update the .csproj files when updating dotnet-sdk
  18   TargetFramework = "net${lib.versions.majorMinor (lib.getVersion dotnet-sdk)}";
  19
  20   library = buildDotnetModule {
  21     name = "project-references-test-library";
  22     src = ./library;
  23     inherit nugetDeps;
  24     env.TargetFramework = TargetFramework;
  25
  26     packNupkg = true;
  27   };
  28
  29   application = buildDotnetModule {
  30     name = "project-references-test-application";
  31     src = ./application;
  32     inherit nugetDeps;
  33     env.TargetFramework = TargetFramework;
  34
  35     projectReferences = [ library ];
  36   };
  37 in
  38
  39 runCommand "project-references-test" { } ''
  40   ${application}/bin/Application
  41   mkdir $out
  42 ''