nixos/lib/make-squashfs.nix

   1 { lib, stdenv, squashfsTools, closureInfo
   2
   3 ,  fileName ? "squashfs"
   4 , # The root directory of the squashfs filesystem is filled with the
   5   # closures of the Nix store paths listed here.
   6   storeContents ? []
   7   # Pseudo files to be added to squashfs image
   8 , pseudoFiles ? []
   9 , noStrip ? false
  10 , # Compression parameters.
  11   # For zstd compression you can use "zstd -Xcompression-level 6".
  12   comp ? "xz -Xdict-size 100%"
  13 , # create hydra build product. will put image in directory instead
  14   # of directly in the store
  15   hydraBuildProduct ? false
  16 }:
  17
  18 let
  19   pseudoFilesArgs = lib.concatMapStrings (f: ''-p "${f}" '') pseudoFiles;
  20   compFlag = if comp == null then "-no-compression" else "-comp ${comp}";
  21 in
  22 stdenv.mkDerivation {
  23   name = "${fileName}${lib.optionalString (!hydraBuildProduct) ".img"}";
  24   __structuredAttrs = true;
  25
  26   nativeBuildInputs = [ squashfsTools ];
  27
  28   buildCommand =
  29     ''
  30       closureInfo=${closureInfo { rootPaths = storeContents; }}
  31
  32       # Also include a manifest of the closures in a format suitable
  33       # for nix-store --load-db.
  34       cp $closureInfo/registration nix-path-registration
  35
  36       imgPath="$out"
  37     '' + lib.optionalString hydraBuildProduct ''
  38
  39       mkdir $out
  40       imgPath="$out/${fileName}.squashfs"
  41     '' + lib.optionalString stdenv.buildPlatform.is32bit ''
  42
  43       # 64 cores on i686 does not work
  44       # fails with FATAL ERROR: mangle2:: xz compress failed with error code 5
  45       if ((NIX_BUILD_CORES > 48)); then
  46         NIX_BUILD_CORES=48
  47       fi
  48     '' + ''
  49
  50       # Generate the squashfs image.
  51       mksquashfs nix-path-registration $(cat $closureInfo/store-paths) $imgPath ${pseudoFilesArgs} \
  52         -no-hardlinks ${lib.optionalString noStrip "-no-strip"} -keep-as-directory -all-root -b 1048576 ${compFlag} \
  53         -processors $NIX_BUILD_CORES
  54     '' + lib.optionalString hydraBuildProduct ''
  55
  56       mkdir -p $out/nix-support
  57       echo "file squashfs-image $out/${fileName}.squashfs" >> $out/nix-support/hydra-build-products
  58     '';
  59 }