nixos/modules/config/fonts/fontdir.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3
   4   cfg = config.fonts.fontDir;
   5
   6   x11Fonts = pkgs.runCommand "X11-fonts" { preferLocalBuild = true; } ''
   7     mkdir -p "$out/share/X11/fonts"
   8     font_regexp='.*\.\(ttf\|ttc\|otb\|otf\|pcf\|pfa\|pfb\|bdf\)\(\.gz\)?'
   9     find ${toString config.fonts.packages} -regex "$font_regexp" \
  10       -exec ln -sf -t "$out/share/X11/fonts" '{}' \;
  11     cd "$out/share/X11/fonts"
  12     ${lib.optionalString cfg.decompressFonts ''
  13       ${pkgs.gzip}/bin/gunzip -f *.gz
  14     ''}
  15     ${pkgs.xorg.mkfontscale}/bin/mkfontscale
  16     ${pkgs.xorg.mkfontdir}/bin/mkfontdir
  17     cat $(find ${pkgs.xorg.fontalias}/ -name fonts.alias) >fonts.alias
  18   '';
  19
  20 in
  21
  22 {
  23
  24   options = {
  25     fonts.fontDir = {
  26
  27       enable = lib.mkOption {
  28         type = lib.types.bool;
  29         default = false;
  30         description = ''
  31           Whether to create a directory with links to all fonts in
  32           {file}`/run/current-system/sw/share/X11/fonts`.
  33         '';
  34       };
  35
  36       decompressFonts = lib.mkOption {
  37         type = lib.types.bool;
  38         default = config.programs.xwayland.enable;
  39         defaultText = lib.literalExpression "config.programs.xwayland.enable";
  40         description = ''
  41           Whether to decompress fonts in
  42           {file}`/run/current-system/sw/share/X11/fonts`.
  43         '';
  44       };
  45
  46     };
  47   };
  48
  49   config = lib.mkIf cfg.enable {
  50
  51     environment.systemPackages = [ x11Fonts ];
  52     environment.pathsToLink = [ "/share/X11/fonts" ];
  53
  54     services.xserver.filesSection = ''
  55       FontPath "${x11Fonts}/share/X11/fonts"
  56     '';
  57
  58   };
  59
  60   imports = [
  61     (lib.mkRenamedOptionModule [ "fonts" "enableFontDir" ] [ "fonts" "fontDir" "enable" ])
  62   ];
  63
  64 }