nixos/modules/config/nsswitch.nix

   1 # Configuration for the Name Service Switch (/etc/nsswitch.conf).
   2 { config, lib, pkgs, ... }:
   3 {
   4   options = {
   5
   6     # NSS modules.  Hacky!
   7     # Only works with nscd!
   8     system.nssModules = lib.mkOption {
   9       type = lib.types.listOf lib.types.path;
  10       internal = true;
  11       default = [ ];
  12       description = ''
  13         Search path for NSS (Name Service Switch) modules.  This allows
  14         several DNS resolution methods to be specified via
  15         {file}`/etc/nsswitch.conf`.
  16       '';
  17       apply = list:
  18         {
  19           inherit list;
  20           path = lib.makeLibraryPath list;
  21         };
  22     };
  23
  24     system.nssDatabases = {
  25       passwd = lib.mkOption {
  26         type = lib.types.listOf lib.types.str;
  27         description = ''
  28           List of passwd entries to configure in {file}`/etc/nsswitch.conf`.
  29
  30           Note that "files" is always prepended while "systemd" is appended if nscd is enabled.
  31
  32           This option only takes effect if nscd is enabled.
  33         '';
  34         default = [ ];
  35       };
  36
  37       group = lib.mkOption {
  38         type = lib.types.listOf lib.types.str;
  39         description = ''
  40           List of group entries to configure in {file}`/etc/nsswitch.conf`.
  41
  42           Note that "files" is always prepended while "systemd" is appended if nscd is enabled.
  43
  44           This option only takes effect if nscd is enabled.
  45         '';
  46         default = [ ];
  47       };
  48
  49       shadow = lib.mkOption {
  50         type = lib.types.listOf lib.types.str;
  51         description = ''
  52           List of shadow entries to configure in {file}`/etc/nsswitch.conf`.
  53
  54           Note that "files" is always prepended.
  55
  56           This option only takes effect if nscd is enabled.
  57         '';
  58         default = [ ];
  59       };
  60
  61       sudoers = lib.mkOption {
  62         type = lib.types.listOf lib.types.str;
  63         description = ''
  64           List of sudoers entries to configure in {file}`/etc/nsswitch.conf`.
  65
  66           Note that "files" is always prepended.
  67
  68           This option only takes effect if nscd is enabled.
  69         '';
  70         default = [ ];
  71       };
  72
  73       hosts = lib.mkOption {
  74         type = lib.types.listOf lib.types.str;
  75         description = ''
  76           List of hosts entries to configure in {file}`/etc/nsswitch.conf`.
  77
  78           Note that "files" is always prepended, and "dns" and "myhostname" are always appended.
  79
  80           This option only takes effect if nscd is enabled.
  81         '';
  82         default = [ ];
  83       };
  84
  85       services = lib.mkOption {
  86         type = lib.types.listOf lib.types.str;
  87         description = ''
  88           List of services entries to configure in {file}`/etc/nsswitch.conf`.
  89
  90           Note that "files" is always prepended.
  91
  92           This option only takes effect if nscd is enabled.
  93         '';
  94         default = [ ];
  95       };
  96     };
  97   };
  98
  99   imports = [
 100     (lib.mkRenamedOptionModule [ "system" "nssHosts" ] [ "system" "nssDatabases" "hosts" ])
 101   ];
 102
 103   config = {
 104     assertions = [
 105       {
 106         assertion = config.system.nssModules.path != "" -> config.services.nscd.enable;
 107         message = ''
 108           Loading NSS modules from system.nssModules (${config.system.nssModules.path}),
 109           requires services.nscd.enable being set to true.
 110
 111           If disabling nscd is really necessary, it is possible to disable loading NSS modules
 112           by setting `system.nssModules = lib.mkForce [];` in your configuration.nix.
 113         '';
 114       }
 115     ];
 116
 117     # Name Service Switch configuration file.  Required by the C
 118     # library.
 119     environment.etc."nsswitch.conf".text = ''
 120       passwd:    ${lib.concatStringsSep " " config.system.nssDatabases.passwd}
 121       group:     ${lib.concatStringsSep " " config.system.nssDatabases.group}
 122       shadow:    ${lib.concatStringsSep " " config.system.nssDatabases.shadow}
 123       sudoers:   ${lib.concatStringsSep " " config.system.nssDatabases.sudoers}
 124
 125       hosts:     ${lib.concatStringsSep " " config.system.nssDatabases.hosts}
 126       networks:  files
 127
 128       ethers:    files
 129       services:  ${lib.concatStringsSep " " config.system.nssDatabases.services}
 130       protocols: files
 131       rpc:       files
 132     '';
 133
 134     system.nssDatabases = {
 135       passwd = lib.mkBefore [ "files" ];
 136       group = lib.mkBefore [ "files" ];
 137       shadow = lib.mkBefore [ "files" ];
 138       sudoers = lib.mkBefore [ "files" ];
 139       hosts = lib.mkMerge [
 140         (lib.mkOrder 998 [ "files" ])
 141         (lib.mkOrder 1499 [ "dns" ])
 142       ];
 143       services = lib.mkBefore [ "files" ];
 144     };
 145   };
 146 }