nixos/modules/config/system-path.nix

   1 # This module defines the packages that appear in
   2 # /run/current-system/sw.
   3 { config, lib, pkgs, ... }:
   4 let
   5
   6   requiredPackages = map (pkg: lib.setPrio ((pkg.meta.priority or lib.meta.defaultPriority) + 3) pkg)
   7     [ pkgs.acl
   8       pkgs.attr
   9       pkgs.bashInteractive # bash with ncurses support
  10       pkgs.bzip2
  11       pkgs.coreutils-full
  12       pkgs.cpio
  13       pkgs.curl
  14       pkgs.diffutils
  15       pkgs.findutils
  16       pkgs.gawk
  17       pkgs.stdenv.cc.libc
  18       pkgs.getent
  19       pkgs.getconf
  20       pkgs.gnugrep
  21       pkgs.gnupatch
  22       pkgs.gnused
  23       pkgs.gnutar
  24       pkgs.gzip
  25       pkgs.xz
  26       pkgs.less
  27       pkgs.libcap
  28       pkgs.ncurses
  29       pkgs.netcat
  30       config.programs.ssh.package
  31       pkgs.mkpasswd
  32       pkgs.procps
  33       pkgs.su
  34       pkgs.time
  35       pkgs.util-linux
  36       pkgs.which
  37       pkgs.zstd
  38     ];
  39
  40   defaultPackageNames =
  41     [ "perl"
  42       "rsync"
  43       "strace"
  44     ];
  45   defaultPackages =
  46     map
  47       (n: let pkg = pkgs.${n};in lib.setPrio ((pkg.meta.priority or lib.meta.defaultPriority) + 3) pkg)
  48       defaultPackageNames;
  49   defaultPackagesText = "[ ${lib.concatMapStringsSep " " (n: "pkgs.${n}") defaultPackageNames } ]";
  50
  51 in
  52
  53 {
  54   options = {
  55
  56     environment = {
  57
  58       systemPackages = lib.mkOption {
  59         type = lib.types.listOf lib.types.package;
  60         default = [];
  61         example = lib.literalExpression "[ pkgs.firefox pkgs.thunderbird ]";
  62         description = ''
  63           The set of packages that appear in
  64           /run/current-system/sw.  These packages are
  65           automatically available to all users, and are
  66           automatically updated every time you rebuild the system
  67           configuration.  (The latter is the main difference with
  68           installing them in the default profile,
  69           {file}`/nix/var/nix/profiles/default`.
  70         '';
  71       };
  72
  73       defaultPackages = lib.mkOption {
  74         type = lib.types.listOf lib.types.package;
  75         default = defaultPackages;
  76         defaultText = lib.literalMD ''
  77           these packages, with their `meta.priority` numerically increased
  78           (thus lowering their installation priority):
  79
  80               ${defaultPackagesText}
  81         '';
  82         example = [];
  83         description = ''
  84           Set of default packages that aren't strictly necessary
  85           for a running system, entries can be removed for a more
  86           minimal NixOS installation.
  87
  88           Like with systemPackages, packages are installed to
  89           {file}`/run/current-system/sw`. They are
  90           automatically available to all users, and are
  91           automatically updated every time you rebuild the system
  92           configuration.
  93         '';
  94       };
  95
  96       pathsToLink = lib.mkOption {
  97         type = lib.types.listOf lib.types.str;
  98         # Note: We need `/lib' to be among `pathsToLink' for NSS modules
  99         # to work.
 100         default = [];
 101         example = ["/"];
 102         description = "List of directories to be symlinked in {file}`/run/current-system/sw`.";
 103       };
 104
 105       extraOutputsToInstall = lib.mkOption {
 106         type = lib.types.listOf lib.types.str;
 107         default = [ ];
 108         example = [ "dev" "info" ];
 109         description = ''
 110           Entries listed here will be appended to the `meta.outputsToInstall` attribute for each package in `environment.systemPackages`, and the files from the corresponding derivation outputs symlinked into {file}`/run/current-system/sw`.
 111
 112           For example, this can be used to install the `dev` and `info` outputs for all packages in the system environment, if they are available.
 113
 114           To use specific outputs instead of configuring them globally, select the corresponding attribute on the package derivation, e.g. `libxml2.dev` or `coreutils.info`.
 115         '';
 116       };
 117
 118       extraSetup = lib.mkOption {
 119         type = lib.types.lines;
 120         default = "";
 121         description = "Shell fragments to be run after the system environment has been created. This should only be used for things that need to modify the internals of the environment, e.g. generating MIME caches. The environment being built can be accessed at $out.";
 122       };
 123
 124     };
 125
 126     system = {
 127
 128       path = lib.mkOption {
 129         internal = true;
 130         description = ''
 131           The packages you want in the boot environment.
 132         '';
 133       };
 134
 135     };
 136
 137   };
 138
 139   config = {
 140
 141     environment.systemPackages = requiredPackages ++ config.environment.defaultPackages;
 142
 143     environment.pathsToLink =
 144       [ "/bin"
 145         "/etc/xdg"
 146         "/etc/gtk-2.0"
 147         "/etc/gtk-3.0"
 148         "/lib" # FIXME: remove and update debug-info.nix
 149         "/sbin"
 150         "/share/emacs"
 151         "/share/hunspell"
 152         "/share/org"
 153         "/share/themes"
 154         "/share/vulkan"
 155         "/share/kservices5"
 156         "/share/kservicetypes5"
 157         "/share/kxmlgui5"
 158         "/share/systemd"
 159         "/share/thumbnailers"
 160       ];
 161
 162     system.path = pkgs.buildEnv {
 163       name = "system-path";
 164       paths = config.environment.systemPackages;
 165       inherit (config.environment) pathsToLink extraOutputsToInstall;
 166       ignoreCollisions = true;
 167       # !!! Hacky, should modularise.
 168       # outputs TODO: note that the tools will often not be linked by default
 169       postBuild =
 170         ''
 171           # Remove wrapped binaries, they shouldn't be accessible via PATH.
 172           find $out/bin -maxdepth 1 -name ".*-wrapped" -type l -delete
 173
 174           if [ -x $out/bin/glib-compile-schemas -a -w $out/share/glib-2.0/schemas ]; then
 175               $out/bin/glib-compile-schemas $out/share/glib-2.0/schemas
 176           fi
 177
 178           ${config.environment.extraSetup}
 179         '';
 180     };
 181
 182   };
 183 }