nixos/modules/config/xdg/portal.nix

   1 { config, pkgs, lib, ... }:
   2
   3 let
   4   inherit (lib)
   5     mkEnableOption
   6     mkIf
   7     mkOption
   8     mkRenamedOptionModule
   9     mkRemovedOptionModule
  10     teams
  11     types;
  12
  13   associationOptions = with types; attrsOf (
  14     coercedTo (either (listOf str) str) (x: lib.concatStringsSep ";" (lib.toList x)) str
  15   );
  16 in
  17
  18 {
  19   imports = [
  20     (mkRenamedOptionModule [ "services" "flatpak" "extraPortals" ] [ "xdg" "portal" "extraPortals" ])
  21     (mkRemovedOptionModule [ "xdg" "portal" "gtkUsePortal" ] "This option has been removed due to being unsupported and discouraged by the GTK developers.")
  22   ];
  23
  24   meta = {
  25     maintainers = teams.freedesktop.members;
  26   };
  27
  28   options.xdg.portal = {
  29     enable =
  30       mkEnableOption ''[xdg desktop integration](https://github.com/flatpak/xdg-desktop-portal)'' // {
  31         default = false;
  32       };
  33
  34     extraPortals = mkOption {
  35       type = types.listOf types.package;
  36       default = [ ];
  37       description = ''
  38         List of additional portals to add to path. Portals allow interaction
  39         with system, like choosing files or taking screenshots. At minimum,
  40         a desktop portal implementation should be listed. GNOME and KDE already
  41         adds `xdg-desktop-portal-gtk`; and
  42         `xdg-desktop-portal-kde` respectively. On other desktop
  43         environments you probably want to add them yourself.
  44       '';
  45     };
  46
  47     xdgOpenUsePortal = mkOption {
  48       type = types.bool;
  49       default = false;
  50       description = ''
  51         Sets environment variable `NIXOS_XDG_OPEN_USE_PORTAL` to `1`
  52         This will make `xdg-open` use the portal to open programs, which resolves bugs involving
  53         programs opening inside FHS envs or with unexpected env vars set from wrappers.
  54         See [#160923](https://github.com/NixOS/nixpkgs/issues/160923) for more info.
  55       '';
  56     };
  57
  58     config = mkOption {
  59       type = types.attrsOf associationOptions;
  60       default = { };
  61       example = {
  62         x-cinnamon = {
  63           default = [ "xapp" "gtk" ];
  64         };
  65         pantheon = {
  66           default = [ "pantheon" "gtk" ];
  67           "org.freedesktop.impl.portal.Secret" = [ "gnome-keyring" ];
  68         };
  69         common = {
  70           default = [ "gtk" ];
  71         };
  72       };
  73       description = ''
  74         Sets which portal backend should be used to provide the implementation
  75         for the requested interface. For details check {manpage}`portals.conf(5)`.
  76
  77         Configs will be linked to `/etc/xdg/xdg-desktop-portal/` with the name `$desktop-portals.conf`
  78         for `xdg.portal.config.$desktop` and `portals.conf` for `xdg.portal.config.common`
  79         as an exception.
  80       '';
  81     };
  82
  83     configPackages = mkOption {
  84       type = types.listOf types.package;
  85       default = [ ];
  86       example = lib.literalExpression "[ pkgs.gnome-session ]";
  87       description = ''
  88         List of packages that provide XDG desktop portal configuration, usually in
  89         the form of `share/xdg-desktop-portal/$desktop-portals.conf`.
  90
  91         Note that configs in `xdg.portal.config` will be preferred if set.
  92       '';
  93     };
  94   };
  95
  96   config =
  97     let
  98       cfg = config.xdg.portal;
  99       packages = [ pkgs.xdg-desktop-portal ] ++ cfg.extraPortals;
 100     in
 101     mkIf cfg.enable {
 102       warnings = lib.optional (cfg.configPackages == [ ] && cfg.config == { }) ''
 103         xdg-desktop-portal 1.17 reworked how portal implementations are loaded, you
 104         should either set `xdg.portal.config` or `xdg.portal.configPackages`
 105         to specify which portal backend to use for the requested interface.
 106
 107         https://github.com/flatpak/xdg-desktop-portal/blob/1.18.1/doc/portals.conf.rst.in
 108
 109         If you simply want to keep the behaviour in < 1.17, which uses the first
 110         portal implementation found in lexicographical order, use the following:
 111
 112         xdg.portal.config.common.default = "*";
 113       '';
 114
 115       assertions = [
 116         {
 117           assertion = cfg.extraPortals != [ ];
 118           message = "Setting xdg.portal.enable to true requires a portal implementation in xdg.portal.extraPortals such as xdg-desktop-portal-gtk or xdg-desktop-portal-kde.";
 119         }
 120       ];
 121
 122       services.dbus.packages = packages;
 123       systemd.packages = packages;
 124
 125       environment = {
 126         systemPackages = packages ++ cfg.configPackages;
 127         pathsToLink = [
 128           # Portal definitions and upstream desktop environment portal configurations.
 129           "/share/xdg-desktop-portal"
 130           # .desktop files to register fallback icon and app name.
 131           "/share/applications"
 132         ];
 133
 134         sessionVariables = {
 135           NIXOS_XDG_OPEN_USE_PORTAL = mkIf cfg.xdgOpenUsePortal "1";
 136           NIX_XDG_DESKTOP_PORTAL_DIR = "/run/current-system/sw/share/xdg-desktop-portal/portals";
 137         };
 138
 139         etc = lib.concatMapAttrs
 140           (desktop: conf: lib.optionalAttrs (conf != { }) {
 141             "xdg/xdg-desktop-portal/${lib.optionalString (desktop != "common") "${desktop}-"}portals.conf".text =
 142               lib.generators.toINI { } { preferred = conf; };
 143           }) cfg.config;
 144       };
 145     };
 146 }