nixos/modules/hardware/printers.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3   cfg = config.hardware.printers;
   4
   5   ensurePrinter = p: let
   6     args = lib.cli.toGNUCommandLineShell {} ({
   7       p = p.name;
   8       v = p.deviceUri;
   9       m = p.model;
  10     } // lib.optionalAttrs (p.location != null) {
  11       L = p.location;
  12     } // lib.optionalAttrs (p.description != null) {
  13       D = p.description;
  14     } // lib.optionalAttrs (p.ppdOptions != {}) {
  15       o = lib.mapAttrsToList (name: value: "${name}=${value}") p.ppdOptions;
  16     });
  17   in ''
  18     ${pkgs.cups}/bin/lpadmin ${args} -E
  19   '';
  20
  21   ensureDefaultPrinter = name: ''
  22     ${pkgs.cups}/bin/lpadmin -d '${name}'
  23   '';
  24
  25   # "graph but not # or /" can't be implemented as regex alone due to missing lookahead support
  26   noInvalidChars = str: lib.all (c: c != "#" && c != "/") (lib.stringToCharacters str);
  27   printerName = (lib.types.addCheck (lib.types.strMatching "[[:graph:]]+") noInvalidChars)
  28     // { description = "printable string without spaces, # and /"; };
  29
  30
  31 in {
  32   options = {
  33     hardware.printers = {
  34       ensureDefaultPrinter = lib.mkOption {
  35         type = lib.types.nullOr printerName;
  36         default = null;
  37         description = ''
  38           Ensures the named printer is the default CUPS printer / printer queue.
  39         '';
  40       };
  41       ensurePrinters = lib.mkOption {
  42         description = ''
  43           Will regularly ensure that the given CUPS printers are configured as declared here.
  44           If a printer's options are manually changed afterwards, they will be overwritten eventually.
  45           This option will never delete any printer, even if removed from this list.
  46           You can check existing printers with {command}`lpstat -s`
  47           and remove printers with {command}`lpadmin -x <printer-name>`.
  48           Printers not listed here can still be manually configured.
  49         '';
  50         default = [];
  51         type = lib.types.listOf (lib.types.submodule {
  52           options = {
  53             name = lib.mkOption {
  54               type = printerName;
  55               example = "BrotherHL_Workroom";
  56               description = ''
  57                 Name of the printer / printer queue.
  58                 May contain any printable characters except "/", "#", and space.
  59               '';
  60             };
  61             location = lib.mkOption {
  62               type = lib.types.nullOr lib.types.str;
  63               default = null;
  64               example = "Workroom";
  65               description = ''
  66                 Optional human-readable location.
  67               '';
  68             };
  69             description = lib.mkOption {
  70               type = lib.types.nullOr lib.types.str;
  71               default = null;
  72               example = "Brother HL-5140";
  73               description = ''
  74                 Optional human-readable description.
  75               '';
  76             };
  77             deviceUri = lib.mkOption {
  78               type = lib.types.str;
  79               example = lib.literalExpression ''
  80                 "ipp://printserver.local/printers/BrotherHL_Workroom"
  81                 "usb://HP/DESKJET%20940C?serial=CN16E6C364BH"
  82               '';
  83               description = ''
  84                 How to reach the printer.
  85                 {command}`lpinfo -v` shows a list of supported device URIs and schemes.
  86               '';
  87             };
  88             model = lib.mkOption {
  89               type = lib.types.str;
  90               example = lib.literalExpression ''
  91                 "gutenprint.''${lib.versions.majorMinor (lib.getVersion pkgs.gutenprint)}://brother-hl-5140/expert"
  92               '';
  93               description = ''
  94                 Location of the ppd driver file for the printer.
  95                 {command}`lpinfo -m` shows a list of supported models.
  96               '';
  97             };
  98             ppdOptions = lib.mkOption {
  99               type = lib.types.attrsOf lib.types.str;
 100               example = {
 101                 PageSize = "A4";
 102                 Duplex = "DuplexNoTumble";
 103               };
 104               default = {};
 105               description = ''
 106                 Sets PPD options for the printer.
 107                 {command}`lpoptions [-p printername] -l` shows supported PPD options for the given printer.
 108               '';
 109             };
 110           };
 111         });
 112       };
 113     };
 114   };
 115
 116   config = lib.mkIf (cfg.ensurePrinters != [] && config.services.printing.enable) {
 117     systemd.services.ensure-printers = {
 118       description = "Ensure NixOS-configured CUPS printers";
 119       wantedBy = [ "multi-user.target" ];
 120       wants = [ "cups.service" ];
 121       after = [ "cups.service" ];
 122
 123       serviceConfig = {
 124         Type = "oneshot";
 125         RemainAfterExit = true;
 126       };
 127
 128       script = lib.concatStringsSep "\n" [
 129         (lib.concatMapStrings ensurePrinter cfg.ensurePrinters)
 130         (lib.optionalString (cfg.ensureDefaultPrinter != null)
 131           (ensureDefaultPrinter cfg.ensureDefaultPrinter))
 132         # Note: if cupsd is "stateless" the service can't be stopped,
 133         # otherwise the configuration will be wiped on the next start.
 134         (lib.optionalString (with config.services.printing; startWhenNeeded && !stateless)
 135           "systemctl stop cups.service")
 136       ];
 137     };
 138   };
 139 }