nixos/modules/hardware/raid/hpsa.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3   hpssacli = pkgs.stdenv.mkDerivation rec {
   4     pname = "hpssacli";
   5     version = "2.40-13.0";
   6
   7     src = pkgs.fetchurl {
   8       urls = [
   9         "https://downloads.linux.hpe.com/SDR/downloads/MCP/Ubuntu/pool/non-free/${pname}-${version}_amd64.deb"
  10         "http://apt.netangels.net/pool/main/h/hpssacli/${pname}-${version}_amd64.deb"
  11       ];
  12       sha256 = "11w7fwk93lmfw0yya4jpjwdmgjimqxx6412sqa166g1pz4jil4sw";
  13     };
  14
  15     nativeBuildInputs = [ pkgs.dpkg ];
  16
  17     unpackPhase = "dpkg -x $src ./";
  18
  19     installPhase = ''
  20       mkdir -p $out/bin $out/share/doc $out/share/man
  21       mv opt/hp/hpssacli/bld/{hpssascripting,hprmstr,hpssacli} $out/bin/
  22       mv opt/hp/hpssacli/bld/*.{license,txt}                   $out/share/doc/
  23       mv usr/man                                               $out/share/
  24
  25       for file in $out/bin/*; do
  26         chmod +w $file
  27         patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
  28                  --set-rpath ${lib.makeLibraryPath [ pkgs.stdenv.cc.cc ]} \
  29                  $file
  30       done
  31     '';
  32
  33     dontStrip = true;
  34
  35     meta = with lib; {
  36       description = "HP Smart Array CLI";
  37       homepage = "https://downloads.linux.hpe.com/SDR/downloads/MCP/Ubuntu/pool/non-free/";
  38       license = licenses.unfreeRedistributable;
  39       platforms = [ "x86_64-linux" ];
  40       maintainers = [ ];
  41     };
  42   };
  43 in {
  44   ###### interface
  45
  46   options = {
  47     hardware.raid.HPSmartArray = {
  48       enable = lib.mkEnableOption "HP Smart Array kernel modules and CLI utility";
  49     };
  50   };
  51
  52   ###### implementation
  53
  54   config = lib.mkIf config.hardware.raid.HPSmartArray.enable {
  55
  56     boot.initrd.kernelModules = [ "sg" ]; /* hpssacli wants it */
  57     boot.initrd.availableKernelModules = [ "hpsa" ];
  58
  59     environment.systemPackages = [ hpssacli ];
  60   };
  61 }