nixos/modules/programs/zsh/zsh-autosuggestions.nix

   1 { config, pkgs, lib, ... }:
   2
   3 let
   4   cfg = config.programs.zsh.autosuggestions;
   5 in
   6 {
   7   imports = [
   8     (lib.mkRenamedOptionModule [ "programs" "zsh" "enableAutosuggestions" ] [ "programs" "zsh" "autosuggestions" "enable" ])
   9   ];
  10
  11   options.programs.zsh.autosuggestions = {
  12
  13     enable = lib.mkEnableOption "zsh-autosuggestions";
  14
  15     highlightStyle = lib.mkOption {
  16       type = lib.types.str;
  17       default = "fg=8"; # https://github.com/zsh-users/zsh-autosuggestions/tree/v0.4.3#suggestion-highlight-style
  18       description = "Highlight style for suggestions ({fore,back}ground color)";
  19       example = "fg=cyan";
  20     };
  21
  22     strategy = lib.mkOption {
  23       type = lib.types.listOf (lib.types.enum [ "history" "completion" "match_prev_cmd" ]);
  24       default = [ "history" ];
  25       description = ''
  26         `ZSH_AUTOSUGGEST_STRATEGY` is an array that specifies how suggestions should be generated.
  27         The strategies in the array are tried successively until a suggestion is found.
  28         There are currently three built-in strategies to choose from:
  29
  30         - `history`: Chooses the most recent match from history.
  31         - `completion`: Chooses a suggestion based on what tab-completion would suggest. (requires `zpty` module)
  32         - `match_prev_cmd`: Like `history`, but chooses the most recent match whose preceding history item matches
  33             the most recently executed command. Note that this strategy won't work as expected with ZSH options that
  34             don't preserve the history order such as `HIST_IGNORE_ALL_DUPS` or `HIST_EXPIRE_DUPS_FIRST`.
  35       '';
  36     };
  37
  38     async = lib.mkOption {
  39       type = lib.types.bool;
  40       default = true;
  41       description = "Whether to fetch suggestions asynchronously";
  42       example = false;
  43     };
  44
  45     extraConfig = lib.mkOption {
  46       type = lib.types.attrsOf lib.types.str;
  47       default = {};
  48       description = "Attribute set with additional configuration values";
  49       example = lib.literalExpression ''
  50         {
  51           "ZSH_AUTOSUGGEST_BUFFER_MAX_SIZE" = "20";
  52         }
  53       '';
  54     };
  55
  56   };
  57
  58   config = lib.mkIf cfg.enable {
  59
  60     programs.zsh.interactiveShellInit = ''
  61       source ${pkgs.zsh-autosuggestions}/share/zsh-autosuggestions/zsh-autosuggestions.zsh
  62
  63       export ZSH_AUTOSUGGEST_HIGHLIGHT_STYLE="${cfg.highlightStyle}"
  64       export ZSH_AUTOSUGGEST_STRATEGY=(${builtins.concatStringsSep " " cfg.strategy})
  65       ${lib.optionalString (!cfg.async) "unset ZSH_AUTOSUGGEST_USE_ASYNC"}
  66
  67       ${builtins.concatStringsSep "\n" (lib.mapAttrsToList (key: value: ''export ${key}="${value}"'') cfg.extraConfig)}
  68     '';
  69
  70   };
  71 }