nixos/modules/programs/zsh/zsh.nix

   1 # This module defines global configuration for the zshell.
   2
   3 { config, lib, options, pkgs, ... }:
   4
   5 let
   6
   7   cfge = config.environment;
   8
   9   cfg = config.programs.zsh;
  10   opt = options.programs.zsh;
  11
  12   zshAliases = builtins.concatStringsSep "\n" (
  13     lib.mapAttrsToList (k: v: "alias -- ${k}=${lib.escapeShellArg v}")
  14       (lib.filterAttrs (k: v: v != null) cfg.shellAliases)
  15   );
  16
  17   zshStartupNotes = ''
  18     # Note that generated /etc/zprofile and /etc/zshrc files do a lot of
  19     # non-standard setup to make zsh usable with no configuration by default.
  20     #
  21     # Which means that unless you explicitly meticulously override everything
  22     # generated, interactions between your ~/.zshrc and these files are likely
  23     # to be rather surprising.
  24     #
  25     # Note however, that you can disable loading of the generated /etc/zprofile
  26     # and /etc/zshrc (you can't disable loading of /etc/zshenv, but it is
  27     # designed to not set anything surprising) by setting `no_global_rcs` option
  28     # in ~/.zshenv:
  29     #
  30     #   echo setopt no_global_rcs >> ~/.zshenv
  31     #
  32     # See "STARTUP/SHUTDOWN FILES" section of zsh(1) for more info.
  33   '';
  34
  35 in
  36
  37 {
  38
  39   options = {
  40
  41     programs.zsh = {
  42
  43       enable = lib.mkOption {
  44         default = false;
  45         description = ''
  46           Whether to configure zsh as an interactive shell. To enable zsh for
  47           a particular user, use the {option}`users.users.<name?>.shell`
  48           option for that user. To enable zsh system-wide use the
  49           {option}`users.defaultUserShell` option.
  50         '';
  51         type = lib.types.bool;
  52       };
  53
  54       shellAliases = lib.mkOption {
  55         default = { };
  56         description = ''
  57           Set of aliases for zsh shell, which overrides {option}`environment.shellAliases`.
  58           See {option}`environment.shellAliases` for an option format description.
  59         '';
  60         type = with lib.types; attrsOf (nullOr (either str path));
  61       };
  62
  63       shellInit = lib.mkOption {
  64         default = "";
  65         description = ''
  66           Shell script code called during zsh shell initialisation.
  67         '';
  68         type = lib.types.lines;
  69       };
  70
  71       loginShellInit = lib.mkOption {
  72         default = "";
  73         description = ''
  74           Shell script code called during zsh login shell initialisation.
  75         '';
  76         type = lib.types.lines;
  77       };
  78
  79       interactiveShellInit = lib.mkOption {
  80         default = "";
  81         description = ''
  82           Shell script code called during interactive zsh shell initialisation.
  83         '';
  84         type = lib.types.lines;
  85       };
  86
  87       promptInit = lib.mkOption {
  88         default = ''
  89           # Note that to manually override this in ~/.zshrc you should run `prompt off`
  90           # before setting your PS1 and etc. Otherwise this will likely to interact with
  91           # your ~/.zshrc configuration in unexpected ways as the default prompt sets
  92           # a lot of different prompt variables.
  93           autoload -U promptinit && promptinit && prompt suse && setopt prompt_sp
  94         '';
  95         description = ''
  96           Shell script code used to initialise the zsh prompt.
  97         '';
  98         type = lib.types.lines;
  99       };
 100
 101       histSize = lib.mkOption {
 102         default = 2000;
 103         description = ''
 104           Change history size.
 105         '';
 106         type = lib.types.int;
 107       };
 108
 109       histFile = lib.mkOption {
 110         default = "$HOME/.zsh_history";
 111         description = ''
 112           Change history file.
 113         '';
 114         type = lib.types.str;
 115       };
 116
 117       setOptions = lib.mkOption {
 118         type = lib.types.listOf lib.types.str;
 119         default = [
 120           "HIST_IGNORE_DUPS"
 121           "SHARE_HISTORY"
 122           "HIST_FCNTL_LOCK"
 123         ];
 124         example = [ "EXTENDED_HISTORY" "RM_STAR_WAIT" ];
 125         description = ''
 126           Configure zsh options. See
 127           {manpage}`zshoptions(1)`.
 128         '';
 129       };
 130
 131       enableCompletion = lib.mkOption {
 132         default = true;
 133         description = ''
 134           Enable zsh completion for all interactive zsh shells.
 135         '';
 136         type = lib.types.bool;
 137       };
 138
 139       enableBashCompletion = lib.mkOption {
 140         default = false;
 141         description = ''
 142           Enable compatibility with bash's programmable completion system.
 143         '';
 144         type = lib.types.bool;
 145       };
 146
 147       enableGlobalCompInit = lib.mkOption {
 148         default = cfg.enableCompletion;
 149         defaultText = lib.literalExpression "config.${opt.enableCompletion}";
 150         description = ''
 151           Enable execution of compinit call for all interactive zsh shells.
 152
 153           This option can be disabled if the user wants to extend its
 154           `fpath` and a custom `compinit`
 155           call in the local config is required.
 156         '';
 157         type = lib.types.bool;
 158       };
 159
 160       enableLsColors = lib.mkOption {
 161         default = true;
 162         description = ''
 163           Enable extra colors in directory listings (used by `ls` and `tree`).
 164         '';
 165         type = lib.types.bool;
 166       };
 167
 168     };
 169
 170   };
 171
 172   config = lib.mkIf cfg.enable {
 173
 174     programs.zsh.shellAliases = builtins.mapAttrs (name: lib.mkDefault) cfge.shellAliases;
 175
 176     environment.etc.zshenv.text =
 177       ''
 178         # /etc/zshenv: DO NOT EDIT -- this file has been generated automatically.
 179         # This file is read for all shells.
 180
 181         # Only execute this file once per shell.
 182         if [ -n "''${__ETC_ZSHENV_SOURCED-}" ]; then return; fi
 183         __ETC_ZSHENV_SOURCED=1
 184
 185         if [ -z "''${__NIXOS_SET_ENVIRONMENT_DONE-}" ]; then
 186             . ${config.system.build.setEnvironment}
 187         fi
 188
 189         HELPDIR="${pkgs.zsh}/share/zsh/$ZSH_VERSION/help"
 190
 191         # Tell zsh how to find installed completions.
 192         for p in ''${(z)NIX_PROFILES}; do
 193             fpath=($p/share/zsh/site-functions $p/share/zsh/$ZSH_VERSION/functions $p/share/zsh/vendor-completions $fpath)
 194         done
 195
 196         # Setup custom shell init stuff.
 197         ${cfge.shellInit}
 198
 199         ${cfg.shellInit}
 200
 201         # Read system-wide modifications.
 202         if test -f /etc/zshenv.local; then
 203             . /etc/zshenv.local
 204         fi
 205       '';
 206
 207     environment.etc.zprofile.text =
 208       ''
 209         # /etc/zprofile: DO NOT EDIT -- this file has been generated automatically.
 210         # This file is read for login shells.
 211         #
 212         ${zshStartupNotes}
 213
 214         # Only execute this file once per shell.
 215         if [ -n "''${__ETC_ZPROFILE_SOURCED-}" ]; then return; fi
 216         __ETC_ZPROFILE_SOURCED=1
 217
 218         # Setup custom login shell init stuff.
 219         ${cfge.loginShellInit}
 220
 221         ${cfg.loginShellInit}
 222
 223         # Read system-wide modifications.
 224         if test -f /etc/zprofile.local; then
 225             . /etc/zprofile.local
 226         fi
 227       '';
 228
 229     environment.etc.zshrc.text =
 230       ''
 231         # /etc/zshrc: DO NOT EDIT -- this file has been generated automatically.
 232         # This file is read for interactive shells.
 233         #
 234         ${zshStartupNotes}
 235
 236         # Only execute this file once per shell.
 237         if [ -n "$__ETC_ZSHRC_SOURCED" -o -n "$NOSYSZSHRC" ]; then return; fi
 238         __ETC_ZSHRC_SOURCED=1
 239
 240         ${lib.optionalString (cfg.setOptions != []) ''
 241           # Set zsh options.
 242           setopt ${builtins.concatStringsSep " " cfg.setOptions}
 243         ''}
 244
 245         # Alternative method of determining short and full hostname.
 246         HOST=${config.networking.fqdnOrHostName}
 247
 248         # Setup command line history.
 249         # Don't export these, otherwise other shells (bash) will try to use same HISTFILE.
 250         SAVEHIST=${builtins.toString cfg.histSize}
 251         HISTSIZE=${builtins.toString cfg.histSize}
 252         HISTFILE=${cfg.histFile}
 253
 254         # Configure sane keyboard defaults.
 255         . /etc/zinputrc
 256
 257         ${lib.optionalString cfg.enableGlobalCompInit ''
 258           # Enable autocompletion.
 259           autoload -U compinit && compinit
 260         ''}
 261
 262         ${lib.optionalString cfg.enableBashCompletion ''
 263           # Enable compatibility with bash's completion system.
 264           autoload -U bashcompinit && bashcompinit
 265         ''}
 266
 267         # Setup custom interactive shell init stuff.
 268         ${cfge.interactiveShellInit}
 269
 270         ${cfg.interactiveShellInit}
 271
 272         ${lib.optionalString cfg.enableLsColors ''
 273           # Extra colors for directory listings.
 274           eval "$(${pkgs.coreutils}/bin/dircolors -b)"
 275         ''}
 276
 277         # Setup aliases.
 278         ${zshAliases}
 279
 280         # Setup prompt.
 281         ${cfg.promptInit}
 282
 283         # Disable some features to support TRAMP.
 284         if [ "$TERM" = dumb ]; then
 285             unsetopt zle prompt_cr prompt_subst
 286             unset RPS1 RPROMPT
 287             PS1='$ '
 288             PROMPT='$ '
 289         fi
 290
 291         # Read system-wide modifications.
 292         if test -f /etc/zshrc.local; then
 293             . /etc/zshrc.local
 294         fi
 295       '';
 296
 297     # Bug in nix flakes:
 298     # If we use `.source` here the path is garbage collected also we point to it with a symlink
 299     # see https://github.com/NixOS/nixpkgs/issues/132732
 300     environment.etc.zinputrc.text = builtins.readFile ./zinputrc;
 301
 302     environment.systemPackages = [ pkgs.zsh ]
 303       ++ lib.optional cfg.enableCompletion pkgs.nix-zsh-completions;
 304
 305     environment.pathsToLink = lib.optional cfg.enableCompletion "/share/zsh";
 306
 307     #users.defaultUserShell = lib.mkDefault "/run/current-system/sw/bin/zsh";
 308
 309     environment.shells =
 310       [
 311         "/run/current-system/sw/bin/zsh"
 312         "${pkgs.zsh}/bin/zsh"
 313       ];
 314
 315   };
 316
 317 }