nixos/modules/services/amqp/rabbitmq.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3   cfg = config.services.rabbitmq;
   4
   5   inherit (builtins) concatStringsSep;
   6
   7   config_file_content = lib.generators.toKeyValue { } cfg.configItems;
   8   config_file = pkgs.writeText "rabbitmq.conf" config_file_content;
   9
  10   advanced_config_file = pkgs.writeText "advanced.config" cfg.config;
  11
  12 in
  13 {
  14
  15   imports = [
  16     (lib.mkRemovedOptionModule [ "services" "rabbitmq" "cookie" ] ''
  17       This option wrote the Erlang cookie to the store, while it should be kept secret.
  18       Please remove it from your NixOS configuration and deploy a cookie securely instead.
  19       The renamed `unsafeCookie` must ONLY be used in isolated non-production environments such as NixOS VM tests.
  20     '')
  21   ];
  22
  23   ###### interface
  24   options = {
  25     services.rabbitmq = {
  26       enable = lib.mkOption {
  27         type = lib.types.bool;
  28         default = false;
  29         description = ''
  30           Whether to enable the RabbitMQ server, an Advanced Message
  31           Queuing Protocol (AMQP) broker.
  32         '';
  33       };
  34
  35       package = lib.mkPackageOption pkgs "rabbitmq-server" { };
  36
  37       listenAddress = lib.mkOption {
  38         default = "127.0.0.1";
  39         example = "";
  40         description = ''
  41           IP address on which RabbitMQ will listen for AMQP
  42           connections.  Set to the empty string to listen on all
  43           interfaces.  Note that RabbitMQ creates a user named
  44           `guest` with password
  45           `guest` by default, so you should delete
  46           this user if you intend to allow external access.
  47
  48           Together with 'port' setting it's mostly an alias for
  49           configItems."listeners.tcp.1" and it's left for backwards
  50           compatibility with previous version of this module.
  51         '';
  52         type = lib.types.str;
  53       };
  54
  55       port = lib.mkOption {
  56         default = 5672;
  57         description = ''
  58           Port on which RabbitMQ will listen for AMQP connections.
  59         '';
  60         type = lib.types.port;
  61       };
  62
  63       dataDir = lib.mkOption {
  64         type = lib.types.path;
  65         default = "/var/lib/rabbitmq";
  66         description = ''
  67           Data directory for rabbitmq.
  68         '';
  69       };
  70
  71       unsafeCookie = lib.mkOption {
  72         default = "";
  73         type = lib.types.str;
  74         description = ''
  75           Erlang cookie is a string of arbitrary length which must
  76           be the same for several nodes to be allowed to communicate.
  77           Leave empty to generate automatically.
  78
  79           Setting the cookie via this option exposes the cookie to the store, which
  80           is not recommended for security reasons.
  81           Only use this option in an isolated non-production environment such as
  82           NixOS VM tests.
  83         '';
  84       };
  85
  86       configItems = lib.mkOption {
  87         default = { };
  88         type = lib.types.attrsOf lib.types.str;
  89         example = lib.literalExpression ''
  90           {
  91             "auth_backends.1.authn" = "rabbit_auth_backend_ldap";
  92             "auth_backends.1.authz" = "rabbit_auth_backend_internal";
  93           }
  94         '';
  95         description = ''
  96           Configuration options in RabbitMQ's new config file format,
  97           which is a simple key-value format that can not express nested
  98           data structures. This is known as the `rabbitmq.conf` file,
  99           although outside NixOS that filename may have Erlang syntax, particularly
 100           prior to RabbitMQ 3.7.0.
 101
 102           If you do need to express nested data structures, you can use
 103           `config` option. Configuration from `config`
 104           will be merged into these options by RabbitMQ at runtime to
 105           form the final configuration.
 106
 107           See https://www.rabbitmq.com/configure.html#config-items
 108           For the distinct formats, see https://www.rabbitmq.com/configure.html#config-file-formats
 109         '';
 110       };
 111
 112       config = lib.mkOption {
 113         default = "";
 114         type = lib.types.str;
 115         description = ''
 116           Verbatim advanced configuration file contents using the Erlang syntax.
 117           This is also known as the `advanced.config` file or the old config format.
 118
 119           `configItems` is preferred whenever possible. However, nested
 120           data structures can only be expressed properly using the `config` option.
 121
 122           The contents of this option will be merged into the `configItems`
 123           by RabbitMQ at runtime to form the final configuration.
 124
 125           See the second table on https://www.rabbitmq.com/configure.html#config-items
 126           For the distinct formats, see https://www.rabbitmq.com/configure.html#config-file-formats
 127         '';
 128       };
 129
 130       plugins = lib.mkOption {
 131         default = [ ];
 132         type = lib.types.listOf lib.types.str;
 133         description = "The names of plugins to enable";
 134       };
 135
 136       pluginDirs = lib.mkOption {
 137         default = [ ];
 138         type = lib.types.listOf lib.types.path;
 139         description = "The list of directories containing external plugins";
 140       };
 141
 142       managementPlugin = {
 143         enable = lib.mkEnableOption "the management plugin";
 144         port = lib.mkOption {
 145           default = 15672;
 146           type = lib.types.port;
 147           description = ''
 148             On which port to run the management plugin
 149           '';
 150         };
 151       };
 152     };
 153   };
 154
 155
 156   ###### implementation
 157   config = lib.mkIf cfg.enable {
 158
 159     # This is needed so we will have 'rabbitmqctl' in our PATH
 160     environment.systemPackages = [ cfg.package ];
 161
 162     services.epmd.enable = true;
 163
 164     users.users.rabbitmq = {
 165       description = "RabbitMQ server user";
 166       home = "${cfg.dataDir}";
 167       createHome = true;
 168       group = "rabbitmq";
 169       uid = config.ids.uids.rabbitmq;
 170     };
 171
 172     users.groups.rabbitmq.gid = config.ids.gids.rabbitmq;
 173
 174     services.rabbitmq.configItems = {
 175       "listeners.tcp.1" = lib.mkDefault "${cfg.listenAddress}:${toString cfg.port}";
 176     } // lib.optionalAttrs cfg.managementPlugin.enable {
 177       "management.tcp.port" = toString cfg.managementPlugin.port;
 178       "management.tcp.ip" = cfg.listenAddress;
 179     };
 180
 181     services.rabbitmq.plugins = lib.optional cfg.managementPlugin.enable "rabbitmq_management";
 182
 183     systemd.services.rabbitmq = {
 184       description = "RabbitMQ Server";
 185
 186       wantedBy = [ "multi-user.target" ];
 187       after = [ "network.target" "epmd.socket" ];
 188       wants = [ "network.target" "epmd.socket" ];
 189
 190       path = [
 191         cfg.package
 192         pkgs.coreutils # mkdir/chown/chmod for preStart
 193       ];
 194
 195       environment = {
 196         RABBITMQ_MNESIA_BASE = "${cfg.dataDir}/mnesia";
 197         RABBITMQ_LOGS = "-";
 198         SYS_PREFIX = "";
 199         RABBITMQ_CONFIG_FILE = config_file;
 200         RABBITMQ_PLUGINS_DIR = lib.concatStringsSep ":" cfg.pluginDirs;
 201         RABBITMQ_ENABLED_PLUGINS_FILE = pkgs.writeText "enabled_plugins" ''
 202           [ ${lib.concatStringsSep "," cfg.plugins} ].
 203         '';
 204       } // lib.optionalAttrs (cfg.config != "") { RABBITMQ_ADVANCED_CONFIG_FILE = advanced_config_file; };
 205
 206       serviceConfig = {
 207         ExecStart = "${cfg.package}/sbin/rabbitmq-server";
 208         ExecStop = "${cfg.package}/sbin/rabbitmqctl shutdown";
 209         User = "rabbitmq";
 210         Group = "rabbitmq";
 211         LogsDirectory = "rabbitmq";
 212         WorkingDirectory = cfg.dataDir;
 213         Type = "notify";
 214         NotifyAccess = "all";
 215         UMask = "0027";
 216         LimitNOFILE = "100000";
 217         Restart = "on-failure";
 218         RestartSec = "10";
 219         TimeoutStartSec = "3600";
 220       };
 221
 222       preStart = ''
 223         ${lib.optionalString (cfg.unsafeCookie != "") ''
 224           install -m 600 <(echo -n ${cfg.unsafeCookie}) ${cfg.dataDir}/.erlang.cookie
 225         ''}
 226       '';
 227     };
 228
 229   };
 230
 231 }