nixos/modules/services/audio/goxlr-utility.nix

   1 { config, lib, pkgs, ... }:
   2
   3 let
   4   cfg = config.services.goxlr-utility;
   5 in
   6
   7 with lib;
   8 {
   9
  10   options = {
  11     services.goxlr-utility = {
  12       enable = mkOption {
  13         default = false;
  14         type = types.bool;
  15         description = ''
  16           Whether to enable goxlr-utility for controlling your TC-Helicon GoXLR or GoXLR Mini
  17         '';
  18       };
  19       package = mkPackageOption pkgs "goxlr-utility" { };
  20       autoStart.xdg = mkOption {
  21         default = true;
  22         type = with types; bool;
  23         description = ''
  24           Start the daemon automatically using XDG autostart.
  25           Sets `xdg.autostart.enable = true` if not already enabled.
  26         '';
  27       };
  28     };
  29   };
  30
  31   config =
  32     let
  33       goxlr-autostart = pkgs.stdenv.mkDerivation {
  34         name = "autostart-goxlr-daemon";
  35         priority = 5;
  36
  37         buildCommand = ''
  38           mkdir -p $out/etc/xdg/autostart
  39           cp ${cfg.package}/share/applications/goxlr-utility.desktop $out/etc/xdg/autostart/goxlr-daemon.desktop
  40           chmod +w $out/etc/xdg/autostart/goxlr-daemon.desktop
  41           echo "X-KDE-autostart-phase=2" >> $out/etc/xdg/autostart/goxlr-daemon.desktop
  42           substituteInPlace $out/etc/xdg/autostart/goxlr-daemon.desktop \
  43             --replace-fail goxlr-launcher goxlr-daemon
  44         '';
  45       };
  46     in
  47     mkIf config.services.goxlr-utility.enable {
  48       services.udev.packages = [ cfg.package ];
  49
  50       xdg.autostart.enable = mkIf cfg.autoStart.xdg true;
  51       environment.systemPackages = mkIf cfg.autoStart.xdg
  52         [
  53           cfg.package
  54           goxlr-autostart
  55         ];
  56     };
  57
  58   meta.maintainers = with maintainers; [ errnoh ];
  59 }