nixos/modules/services/development/hoogle.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3
   4   cfg = config.services.hoogle;
   5
   6   hoogleEnv = pkgs.buildEnv {
   7     name = "hoogle";
   8     paths = [ (cfg.haskellPackages.ghcWithHoogle cfg.packages) ];
   9   };
  10
  11 in {
  12
  13   options.services.hoogle = {
  14     enable = lib.mkEnableOption "Haskell documentation server";
  15
  16     port = lib.mkOption {
  17       type = lib.types.port;
  18       default = 8080;
  19       description = ''
  20         Port number Hoogle will be listening to.
  21       '';
  22     };
  23
  24     packages = lib.mkOption {
  25       type = lib.types.functionTo (lib.types.listOf lib.types.package);
  26       default = hp: [];
  27       defaultText = lib.literalExpression "hp: []";
  28       example = lib.literalExpression "hp: with hp; [ text lens ]";
  29       description = ''
  30         The Haskell packages to generate documentation for.
  31
  32         The option value is a function that takes the package set specified in
  33         the {var}`haskellPackages` option as its sole parameter and
  34         returns a list of packages.
  35       '';
  36     };
  37
  38     haskellPackages = lib.mkOption {
  39       description = "Which haskell package set to use.";
  40       type = lib.types.attrs;
  41       default = pkgs.haskellPackages;
  42       defaultText = lib.literalExpression "pkgs.haskellPackages";
  43     };
  44
  45     home = lib.mkOption {
  46       type = lib.types.str;
  47       description = "Url for hoogle logo";
  48       default = "https://hoogle.haskell.org";
  49     };
  50
  51     host = lib.mkOption {
  52       type = lib.types.str;
  53       description = "Set the host to bind on.";
  54       default = "127.0.0.1";
  55     };
  56
  57     extraOptions = lib.mkOption {
  58       type = lib.types.listOf lib.types.str;
  59       default = [];
  60       example = [ "--no-security-headers" ];
  61       description = ''
  62         Additional command-line arguments to pass to
  63         {command}`hoogle server`
  64       '';
  65     };
  66   };
  67
  68   config = lib.mkIf cfg.enable {
  69     systemd.services.hoogle = {
  70       description = "Haskell documentation server";
  71
  72       wantedBy = [ "multi-user.target" ];
  73
  74       serviceConfig = {
  75         Restart = "always";
  76         ExecStart = ''
  77           ${hoogleEnv}/bin/hoogle server --local --port ${toString cfg.port} --home ${cfg.home} --host ${cfg.host} \
  78             ${lib.concatStringsSep " " cfg.extraOptions}
  79         '';
  80
  81         DynamicUser = true;
  82
  83         ProtectHome = true;
  84
  85         RuntimeDirectory = "hoogle";
  86         WorkingDirectory = "%t/hoogle";
  87       };
  88     };
  89   };
  90
  91 }