nixos/modules/services/misc/octoprint.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3
   4   cfg = config.services.octoprint;
   5
   6   baseConfig = {
   7     plugins.curalegacy.cura_engine = "${pkgs.curaengine_stable}/bin/CuraEngine";
   8     server.host = cfg.host;
   9     server.port = cfg.port;
  10     webcam.ffmpeg = "${pkgs.ffmpeg.bin}/bin/ffmpeg";
  11   };
  12
  13   fullConfig = lib.recursiveUpdate cfg.extraConfig baseConfig;
  14
  15   cfgUpdate = pkgs.writeText "octoprint-config.yaml" (builtins.toJSON fullConfig);
  16
  17   pluginsEnv = package.python.withPackages (ps: [ ps.octoprint ] ++ (cfg.plugins ps));
  18
  19   package = pkgs.octoprint;
  20
  21 in
  22 {
  23   ##### interface
  24
  25   options = {
  26
  27     services.octoprint = {
  28
  29       enable = lib.mkEnableOption "OctoPrint, web interface for 3D printers";
  30
  31       host = lib.mkOption {
  32         type = lib.types.str;
  33         default = "0.0.0.0";
  34         description = ''
  35           Host to bind OctoPrint to.
  36         '';
  37       };
  38
  39       port = lib.mkOption {
  40         type = lib.types.port;
  41         default = 5000;
  42         description = ''
  43           Port to bind OctoPrint to.
  44         '';
  45       };
  46
  47       openFirewall = lib.mkOption {
  48         type = lib.types.bool;
  49         default = false;
  50         description = "Open ports in the firewall for OctoPrint.";
  51       };
  52
  53       user = lib.mkOption {
  54         type = lib.types.str;
  55         default = "octoprint";
  56         description = "User for the daemon.";
  57       };
  58
  59       group = lib.mkOption {
  60         type = lib.types.str;
  61         default = "octoprint";
  62         description = "Group for the daemon.";
  63       };
  64
  65       stateDir = lib.mkOption {
  66         type = lib.types.path;
  67         default = "/var/lib/octoprint";
  68         description = "State directory of the daemon.";
  69       };
  70
  71       plugins = lib.mkOption {
  72         type = lib.types.functionTo (lib.types.listOf lib.types.package);
  73         default = plugins: [ ];
  74         defaultText = lib.literalExpression "plugins: []";
  75         example = lib.literalExpression "plugins: with plugins; [ themeify stlviewer ]";
  76         description = "Additional plugins to be used. Available plugins are passed through the plugins input.";
  77       };
  78
  79       extraConfig = lib.mkOption {
  80         type = lib.types.attrs;
  81         default = { };
  82         description = "Extra options which are added to OctoPrint's YAML configuration file.";
  83       };
  84
  85     };
  86
  87   };
  88
  89   ##### implementation
  90
  91   config = lib.mkIf cfg.enable {
  92
  93     users.users = lib.optionalAttrs (cfg.user == "octoprint") {
  94       octoprint = {
  95         group = cfg.group;
  96         uid = config.ids.uids.octoprint;
  97       };
  98     };
  99
 100     users.groups = lib.optionalAttrs (cfg.group == "octoprint") {
 101       octoprint.gid = config.ids.gids.octoprint;
 102     };
 103
 104     systemd.tmpfiles.rules = [
 105       "d '${cfg.stateDir}' - ${cfg.user} ${cfg.group} - -"
 106       # this will allow octoprint access to raspberry specific hardware to check for throttling
 107       # read-only will not work: "VCHI initialization failed" error
 108       "a /dev/vchiq - - - - u:octoprint:rw"
 109     ];
 110
 111     systemd.services.octoprint = {
 112       description = "OctoPrint, web interface for 3D printers";
 113       wantedBy = [ "multi-user.target" ];
 114       after = [ "network.target" ];
 115       path = [ pluginsEnv ];
 116
 117       preStart = ''
 118         if [ -e "${cfg.stateDir}/config.yaml" ]; then
 119           ${pkgs.yaml-merge}/bin/yaml-merge "${cfg.stateDir}/config.yaml" "${cfgUpdate}" > "${cfg.stateDir}/config.yaml.tmp"
 120           mv "${cfg.stateDir}/config.yaml.tmp" "${cfg.stateDir}/config.yaml"
 121         else
 122           cp "${cfgUpdate}" "${cfg.stateDir}/config.yaml"
 123           chmod 600 "${cfg.stateDir}/config.yaml"
 124         fi
 125       '';
 126
 127       serviceConfig = {
 128         ExecStart = "${pluginsEnv}/bin/octoprint serve -b ${cfg.stateDir}";
 129         User = cfg.user;
 130         Group = cfg.group;
 131         SupplementaryGroups = [
 132           "dialout"
 133         ];
 134       };
 135     };
 136
 137     networking.firewall.allowedTCPPorts = lib.mkIf cfg.openFirewall [ cfg.port ];
 138   };
 139 }