nixos/modules/services/monitoring/alloy.nix

   1 { lib, pkgs, config, ... }:
   2 with lib;
   3 let
   4   cfg = config.services.alloy;
   5 in
   6 {
   7   meta = {
   8     maintainers = with maintainers; [ flokli hbjydev ];
   9   };
  10
  11   options.services.alloy = {
  12     enable = mkEnableOption "Grafana Alloy";
  13
  14     package = mkPackageOption pkgs "grafana-alloy" { };
  15
  16     configPath = mkOption {
  17       type = lib.types.path;
  18       default = "/etc/alloy";
  19       description = ''
  20         Alloy configuration file/directory path.
  21
  22         We default to `/etc/alloy` here, and expect the user to configure a
  23         configuration file via `environment.etc."alloy/config.alloy"`.
  24
  25         This allows config reload, contrary to specifying a store path.
  26         A `reloadTrigger` for `config.alloy` is configured.
  27
  28         Other `*.alloy` files in the same directory (ignoring subdirs) are also
  29         honored, but it's necessary to manually extend
  30         `systemd.services.alloy.reloadTriggers` to enable config reload
  31         during nixos-rebuild switch.
  32
  33         This can also point to another directory containing `*.alloy` files, or
  34         a single Alloy file in the Nix store (at the cost of reload).
  35
  36         Component names must be unique across all Alloy configuration files, and
  37         configuration blocks must not be repeated.
  38
  39         Alloy will continue to run if subsequent reloads of the configuration
  40         file fail, potentially marking components as unhealthy depending on
  41         the nature of the failure. When this happens, Alloy will continue
  42         functioning in the last valid state.
  43       '';
  44     };
  45
  46     extraFlags = mkOption {
  47       type = with lib.types; listOf str;
  48       default = [ ];
  49       example = [ "--server.http.listen-addr=127.0.0.1:12346" "--disable-reporting" ];
  50       description = ''
  51         Extra command-line flags passed to {command}`alloy run`.
  52
  53         See <https://grafana.com/docs/alloy/latest/reference/cli/run/>
  54       '';
  55     };
  56   };
  57
  58
  59   config = mkIf cfg.enable {
  60     systemd.services.alloy = {
  61       wantedBy = [ "multi-user.target" ];
  62       reloadTriggers = [ config.environment.etc."alloy/config.alloy".source or null ];
  63       serviceConfig = {
  64         Restart = "always";
  65         DynamicUser = true;
  66         RestartSec = 2;
  67         SupplementaryGroups = [
  68           # allow to read the systemd journal for loki log forwarding
  69           "systemd-journal"
  70         ];
  71         ExecStart = "${lib.getExe cfg.package} run ${cfg.configPath} ${escapeShellArgs cfg.extraFlags}";
  72         ExecReload = "${pkgs.coreutils}/bin/kill -SIGHUP $MAINPID";
  73         ConfigurationDirectory = "alloy";
  74         StateDirectory = "alloy";
  75         WorkingDirectory = "%S/alloy";
  76         Type = "simple";
  77       };
  78     };
  79   };
  80 }