nixos/modules/services/networking/cntlm.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3
   4   cfg = config.services.cntlm;
   5
   6   configFile = if cfg.configText != "" then
   7     pkgs.writeText "cntlm.conf" ''
   8       ${cfg.configText}
   9     ''
  10     else
  11     pkgs.writeText "lighttpd.conf" ''
  12       # Cntlm Authentication Proxy Configuration
  13       Username ${cfg.username}
  14       Domain ${cfg.domain}
  15       Password ${cfg.password}
  16       ${lib.optionalString (cfg.netbios_hostname != "") "Workstation ${cfg.netbios_hostname}"}
  17       ${lib.concatMapStrings (entry: "Proxy ${entry}\n") cfg.proxy}
  18       ${lib.optionalString (cfg.noproxy != []) "NoProxy ${lib.concatStringsSep ", " cfg.noproxy}"}
  19
  20       ${lib.concatMapStrings (port: ''
  21         Listen ${toString port}
  22       '') cfg.port}
  23
  24       ${cfg.extraConfig}
  25     '';
  26
  27 in
  28
  29 {
  30
  31   options.services.cntlm = {
  32
  33     enable = lib.mkEnableOption "cntlm, which starts a local proxy";
  34
  35     username = lib.mkOption {
  36       type = lib.types.str;
  37       description = ''
  38         Proxy account name, without the possibility to include domain name ('at' sign is interpreted literally).
  39       '';
  40     };
  41
  42     domain = lib.mkOption {
  43       type = lib.types.str;
  44       description = "Proxy account domain/workgroup name.";
  45     };
  46
  47     password = lib.mkOption {
  48       default = "/etc/cntlm.password";
  49       type = lib.types.str;
  50       description = "Proxy account password. Note: use chmod 0600 on /etc/cntlm.password for security.";
  51     };
  52
  53     netbios_hostname = lib.mkOption {
  54       type = lib.types.str;
  55       default = "";
  56       description = ''
  57         The hostname of your machine.
  58       '';
  59     };
  60
  61     proxy = lib.mkOption {
  62       type = lib.types.listOf lib.types.str;
  63       description = ''
  64         A list of NTLM/NTLMv2 authenticating HTTP proxies.
  65
  66         Parent proxy, which requires authentication. The same as proxy on the command-line, can be used more than  once  to  specify  unlimited
  67         number  of  proxies.  Should  one proxy fail, cntlm automatically moves on to the next one. The connect request fails only if the whole
  68         list of proxies is scanned and (for each request) and found to be invalid. Command-line takes precedence over the configuration file.
  69       '';
  70       example = [ "proxy.example.com:81" ];
  71     };
  72
  73     noproxy = lib.mkOption {
  74       description = ''
  75         A list of domains where the proxy is skipped.
  76       '';
  77       default = [];
  78       type = lib.types.listOf lib.types.str;
  79       example = [ "*.example.com" "example.com" ];
  80     };
  81
  82     port = lib.mkOption {
  83       default = [3128];
  84       type = lib.types.listOf lib.types.port;
  85       description = "Specifies on which ports the cntlm daemon listens.";
  86     };
  87
  88     extraConfig = lib.mkOption {
  89       type = lib.types.lines;
  90       default = "";
  91       description = "Additional config appended to the end of the generated {file}`cntlm.conf`.";
  92     };
  93
  94     configText = lib.mkOption {
  95        type = lib.types.lines;
  96        default = "";
  97        description = "Verbatim contents of {file}`cntlm.conf`.";
  98     };
  99
 100   };
 101
 102   ###### implementation
 103
 104   config = lib.mkIf cfg.enable {
 105     systemd.services.cntlm = {
 106       description = "CNTLM is an NTLM / NTLM Session Response / NTLMv2 authenticating HTTP proxy";
 107       after = [ "network.target" ];
 108       wantedBy = [ "multi-user.target" ];
 109       serviceConfig = {
 110         User = "cntlm";
 111         ExecStart = ''
 112           ${pkgs.cntlm}/bin/cntlm -U cntlm -c ${configFile} -v -f
 113         '';
 114       };
 115     };
 116
 117     users.users.cntlm = {
 118       name = "cntlm";
 119       description = "cntlm system-wide daemon";
 120       isSystemUser = true;
 121     };
 122   };
 123 }