nixos/modules/services/networking/zerotierone.nix

   1 { config, lib, pkgs, ... }:
   2
   3 with lib;
   4
   5 let
   6   cfg = config.services.zerotierone;
   7
   8   settingsFormat = pkgs.formats.json {};
   9   localConfFile = settingsFormat.generate "zt-local.conf" cfg.localConf;
  10   localConfFilePath = "/var/lib/zerotier-one/local.conf";
  11 in
  12 {
  13   options.services.zerotierone.enable = mkEnableOption "ZeroTierOne";
  14
  15   options.services.zerotierone.joinNetworks = mkOption {
  16     default = [];
  17     example = [ "a8a2c3c10c1a68de" ];
  18     type = types.listOf types.str;
  19     description = ''
  20       List of ZeroTier Network IDs to join on startup.
  21       Note that networks are only ever joined, but not automatically left after removing them from the list.
  22       To remove networks, use the ZeroTier CLI: `zerotier-cli leave <network-id>`
  23     '';
  24   };
  25
  26   options.services.zerotierone.port = mkOption {
  27     default = 9993;
  28     type = types.port;
  29     description = ''
  30       Network port used by ZeroTier.
  31     '';
  32   };
  33
  34   options.services.zerotierone.package = mkPackageOption pkgs "zerotierone" { };
  35
  36   options.services.zerotierone.localConf = mkOption {
  37     default = {};
  38     description = ''
  39       Optional configuration to be written to the Zerotier JSON-based local.conf.
  40       If set, the configuration will be symlinked to `/var/lib/zerotier-one/local.conf` at build time.
  41       To understand the configuration format, refer to https://docs.zerotier.com/config/#local-configuration-options.
  42     '';
  43     example = {
  44       settings.allowTcpFallbackRelay = false;
  45     };
  46     type = settingsFormat.type;
  47   };
  48
  49   config = mkIf cfg.enable {
  50     systemd.services.zerotierone = {
  51       description = "ZeroTierOne";
  52
  53       wantedBy = [ "multi-user.target" ];
  54       after = [ "network.target" ];
  55       wants = [ "network-online.target" ];
  56
  57       path = [ cfg.package ];
  58
  59       preStart = ''
  60         mkdir -p /var/lib/zerotier-one/networks.d
  61         chmod 700 /var/lib/zerotier-one
  62         chown -R root:root /var/lib/zerotier-one
  63
  64         # cleans up old symlinks also if we unset localConf
  65         if [[ -L "${localConfFilePath}" && "$(readlink "${localConfFilePath}")" =~ ^${builtins.storeDir}.* ]]; then
  66           rm ${localConfFilePath}
  67         fi
  68       '' + (concatMapStrings (netId: ''
  69         touch "/var/lib/zerotier-one/networks.d/${netId}.conf"
  70       '') cfg.joinNetworks) + lib.optionalString (cfg.localConf != {}) ''
  71         # in case the user has applied manual changes to the local.conf, we backup the file
  72         if [ -f "${localConfFilePath}" ]; then
  73           mv ${localConfFilePath} ${localConfFilePath}.bak
  74         fi
  75         ln -s ${localConfFile} ${localConfFilePath}
  76       '';
  77
  78       serviceConfig = {
  79         ExecStart = "${cfg.package}/bin/zerotier-one -p${toString cfg.port}";
  80         Restart = "always";
  81         KillMode = "process";
  82         TimeoutStopSec = 5;
  83       };
  84     };
  85
  86     # ZeroTier does not issue DHCP leases, but some strangers might...
  87     networking.dhcpcd.denyInterfaces = [ "zt*" ];
  88
  89     # ZeroTier receives UDP transmissions
  90     networking.firewall.allowedUDPPorts = [ cfg.port ];
  91
  92     environment.systemPackages = [ cfg.package ];
  93
  94     # Prevent systemd from potentially changing the MAC address
  95     systemd.network.links."50-zerotier" = {
  96       matchConfig = {
  97         OriginalName = "zt*";
  98       };
  99       linkConfig = {
 100         AutoNegotiation = false;
 101         MACAddressPolicy = "none";
 102       };
 103     };
 104   };
 105 }