nixos/modules/services/web-servers/minio.nix

   1 { config, lib, pkgs, ... }:
   2
   3 with lib;
   4
   5 let
   6   cfg = config.services.minio;
   7
   8   legacyCredentials = cfg: pkgs.writeText "minio-legacy-credentials" ''
   9     MINIO_ROOT_USER=${cfg.accessKey}
  10     MINIO_ROOT_PASSWORD=${cfg.secretKey}
  11   '';
  12 in
  13 {
  14   meta.maintainers = [ maintainers.bachp ];
  15
  16   options.services.minio = {
  17     enable = mkEnableOption "Minio Object Storage";
  18
  19     listenAddress = mkOption {
  20       default = ":9000";
  21       type = types.str;
  22       description = "IP address and port of the server.";
  23     };
  24
  25     consoleAddress = mkOption {
  26       default = ":9001";
  27       type = types.str;
  28       description = "IP address and port of the web UI (console).";
  29     };
  30
  31     dataDir = mkOption {
  32       default = [ "/var/lib/minio/data" ];
  33       type = types.listOf (types.either types.path types.str);
  34       description = "The list of data directories or nodes for storing the objects. Use one path for regular operation and the minimum of 4 endpoints for Erasure Code mode.";
  35     };
  36
  37     configDir = mkOption {
  38       default = "/var/lib/minio/config";
  39       type = types.path;
  40       description = "The config directory, for the access keys and other settings.";
  41     };
  42
  43     accessKey = mkOption {
  44       default = "";
  45       type = types.str;
  46       description = ''
  47         Access key of 5 to 20 characters in length that clients use to access the server.
  48         This overrides the access key that is generated by minio on first startup and stored inside the
  49         `configDir` directory.
  50       '';
  51     };
  52
  53     secretKey = mkOption {
  54       default = "";
  55       type = types.str;
  56       description = ''
  57         Specify the Secret key of 8 to 40 characters in length that clients use to access the server.
  58         This overrides the secret key that is generated by minio on first startup and stored inside the
  59         `configDir` directory.
  60       '';
  61     };
  62
  63     rootCredentialsFile = mkOption {
  64       type = types.nullOr types.path;
  65       default = null;
  66       description = ''
  67         File containing the MINIO_ROOT_USER, default is "minioadmin", and
  68         MINIO_ROOT_PASSWORD (length >= 8), default is "minioadmin"; in the format of
  69         an EnvironmentFile=, as described by systemd.exec(5).
  70       '';
  71       example = "/etc/nixos/minio-root-credentials";
  72     };
  73
  74     region = mkOption {
  75       default = "us-east-1";
  76       type = types.str;
  77       description = ''
  78         The physical location of the server. By default it is set to us-east-1, which is same as AWS S3's and Minio's default region.
  79       '';
  80     };
  81
  82     browser = mkOption {
  83       default = true;
  84       type = types.bool;
  85       description = "Enable or disable access to web UI.";
  86     };
  87
  88     package = mkPackageOption pkgs "minio" { };
  89   };
  90
  91   config = mkIf cfg.enable {
  92     warnings = optional ((cfg.accessKey != "") || (cfg.secretKey != "")) "services.minio.`accessKey` and services.minio.`secretKey` are deprecated, please use services.minio.`rootCredentialsFile` instead.";
  93
  94     systemd = lib.mkMerge [{
  95       tmpfiles.rules = [
  96         "d '${cfg.configDir}' - minio minio - -"
  97       ] ++ (map (x: "d '" + x + "' - minio minio - - ") (builtins.filter lib.types.path.check cfg.dataDir));
  98
  99       services.minio = {
 100         description = "Minio Object Storage";
 101         wants = [ "network-online.target" ];
 102         after = [ "network-online.target" ];
 103         wantedBy = [ "multi-user.target" ];
 104         serviceConfig = {
 105           ExecStart = "${cfg.package}/bin/minio server --json --address ${cfg.listenAddress} --console-address ${cfg.consoleAddress} --config-dir=${cfg.configDir} ${toString cfg.dataDir}";
 106           Type = "simple";
 107           User = "minio";
 108           Group = "minio";
 109           LimitNOFILE = 65536;
 110           EnvironmentFile =
 111             if (cfg.rootCredentialsFile != null) then cfg.rootCredentialsFile
 112             else if ((cfg.accessKey != "") || (cfg.secretKey != "")) then (legacyCredentials cfg)
 113             else null;
 114         };
 115         environment = {
 116           MINIO_REGION = "${cfg.region}";
 117           MINIO_BROWSER = "${if cfg.browser then "on" else "off"}";
 118         };
 119       };
 120     }
 121
 122       (lib.mkIf (cfg.rootCredentialsFile != null) {
 123         # The service will fail if the credentials file is missing
 124         services.minio.unitConfig.ConditionPathExists = cfg.rootCredentialsFile;
 125
 126         # The service will not restart if the credentials file has
 127         # been changed. This can cause stale root credentials.
 128         paths.minio-root-credentials = {
 129           wantedBy = [ "multi-user.target" ];
 130
 131           pathConfig = {
 132             PathChanged = [ cfg.rootCredentialsFile ];
 133             Unit = "minio-restart.service";
 134           };
 135         };
 136
 137         services.minio-restart = {
 138           description = "Restart MinIO";
 139
 140           script = ''
 141             systemctl restart minio.service
 142           '';
 143
 144           serviceConfig = {
 145             Type = "oneshot";
 146             Restart = "on-failure";
 147             RestartSec = 5;
 148           };
 149         };
 150       })];
 151
 152     users.users.minio = {
 153       group = "minio";
 154       uid = config.ids.uids.minio;
 155     };
 156
 157     users.groups.minio.gid = config.ids.uids.minio;
 158   };
 159 }