nixos/modules/services/x11/desktop-managers/gnome.md

   1 # GNOME Desktop {#chap-gnome}
   2
   3 GNOME provides a simple, yet full-featured desktop environment with a focus on productivity. Its Mutter compositor supports both Wayland and X server, and the GNOME Shell user interface is fully customizable by extensions.
   4
   5 ## Enabling GNOME {#sec-gnome-enable}
   6
   7 All of the core apps, optional apps, games, and core developer tools from GNOME are available.
   8
   9 To enable the GNOME desktop use:
  10
  11 ```nix
  12 {
  13   services.xserver.desktopManager.gnome.enable = true;
  14   services.xserver.displayManager.gdm.enable = true;
  15 }
  16 ```
  17
  18 ::: {.note}
  19 While it is not strictly necessary to use GDM as the display manager with GNOME, it is recommended, as some features such as screen lock [might not work](#sec-gnome-faq-can-i-use-lightdm-with-gnome) without it.
  20 :::
  21
  22 The default applications used in NixOS are very minimal, inspired by the defaults used in [gnome-build-meta](https://gitlab.gnome.org/GNOME/gnome-build-meta/blob/40.0/elements/core/meta-gnome-core-utilities.bst).
  23
  24 ### GNOME without the apps {#sec-gnome-without-the-apps}
  25
  26 If you’d like to only use the GNOME desktop and not the apps, you can disable them with:
  27
  28 ```nix
  29 {
  30   services.gnome.core-utilities.enable = false;
  31 }
  32 ```
  33
  34 and none of them will be installed.
  35
  36 If you’d only like to omit a subset of the core utilities, you can use
  37 [](#opt-environment.gnome.excludePackages).
  38 Note that this mechanism can only exclude core utilities, games and core developer tools.
  39
  40 ### Disabling GNOME services {#sec-gnome-disabling-services}
  41
  42 It is also possible to disable many of the [core services](https://github.com/NixOS/nixpkgs/blob/b8ec4fd2a4edc4e30d02ba7b1a2cc1358f3db1d5/nixos/modules/services/x11/desktop-managers/gnome.nix#L329-L348). For example, if you do not need indexing files, you can disable Tracker with:
  43
  44 ```nix
  45 {
  46   services.gnome.tracker-miners.enable = false;
  47   services.gnome.tracker.enable = false;
  48 }
  49 ```
  50
  51 Note, however, that doing so is not supported and might break some applications. Notably, GNOME Music cannot work without Tracker.
  52
  53 ### GNOME games {#sec-gnome-games}
  54
  55 You can install all of the GNOME games with:
  56
  57 ```nix
  58 {
  59   services.gnome.games.enable = true;
  60 }
  61 ```
  62
  63 ### GNOME core developer tools {#sec-gnome-core-developer-tools}
  64
  65 You can install GNOME core developer tools with:
  66
  67 ```nix
  68 {
  69   services.gnome.core-developer-tools.enable = true;
  70 }
  71 ```
  72
  73 ## Enabling GNOME Flashback {#sec-gnome-enable-flashback}
  74
  75 GNOME Flashback provides a desktop environment based on the classic GNOME 2 architecture. You can enable the default GNOME Flashback session, which uses the Metacity window manager, with:
  76
  77 ```nix
  78 {
  79   services.xserver.desktopManager.gnome.flashback.enableMetacity = true;
  80 }
  81 ```
  82
  83 It is also possible to create custom sessions that replace Metacity with a different window manager using [](#opt-services.xserver.desktopManager.gnome.flashback.customSessions).
  84
  85 The following example uses `xmonad` window manager:
  86
  87 ```nix
  88 {
  89   services.xserver.desktopManager.gnome.flashback.customSessions = [
  90     {
  91       wmName = "xmonad";
  92       wmLabel = "XMonad";
  93       wmCommand = "${pkgs.haskellPackages.xmonad}/bin/xmonad";
  94       enableGnomePanel = false;
  95     }
  96   ];
  97 }
  98 ```
  99
 100 ## Icons and GTK Themes {#sec-gnome-icons-and-gtk-themes}
 101
 102 Icon themes and GTK themes don’t require any special option to install in NixOS.
 103
 104 You can add them to [](#opt-environment.systemPackages) and switch to them with GNOME Tweaks.
 105 If you’d like to do this manually in dconf, change the values of the following keys:
 106
 107 ```
 108 /org/gnome/desktop/interface/gtk-theme
 109 /org/gnome/desktop/interface/icon-theme
 110 ```
 111
 112 in `dconf-editor`
 113
 114 ## Shell Extensions {#sec-gnome-shell-extensions}
 115
 116 Most Shell extensions are packaged under the `gnomeExtensions` attribute.
 117 Some packages that include Shell extensions, like `gpaste`, don’t have their extension decoupled under this attribute.
 118
 119 You can install them like any other package:
 120
 121 ```nix
 122 {
 123   environment.systemPackages = [
 124     gnomeExtensions.dash-to-dock
 125     gnomeExtensions.gsconnect
 126     gnomeExtensions.mpris-indicator-button
 127   ];
 128 }
 129 ```
 130
 131 Unfortunately, we lack a way for these to be managed in a completely declarative way.
 132 So you have to enable them manually with an Extensions application.
 133 It is possible to use a [GSettings override](#sec-gnome-gsettings-overrides) for this on `org.gnome.shell.enabled-extensions`, but that will only influence the default value.
 134
 135 ## GSettings Overrides {#sec-gnome-gsettings-overrides}
 136
 137 Majority of software building on the GNOME platform use GLib’s [GSettings](https://developer.gnome.org/gio/unstable/GSettings.html) system to manage runtime configuration. For our purposes, the system consists of XML schemas describing the individual configuration options, stored in the package, and a settings backend, where the values of the settings are stored. On NixOS, like on most Linux distributions, dconf database is used as the backend.
 138
 139 [GSettings vendor overrides](https://developer.gnome.org/gio/unstable/GSettings.html#id-1.4.19.2.9.25) can be used to adjust the default values for settings of the GNOME desktop and apps by replacing the default values specified in the XML schemas. Using overrides will allow you to pre-seed user settings before you even start the session.
 140
 141 ::: {.warning}
 142 Overrides really only change the default values for GSettings keys so if you or an application changes the setting value, the value set by the override will be ignored. Until [NixOS’s dconf module implements changing values](https://github.com/NixOS/nixpkgs/issues/54150), you will either need to keep that in mind and clear the setting from the backend using `dconf reset` command when that happens, or use the [module from home-manager](https://nix-community.github.io/home-manager/options.html#opt-dconf.settings).
 143 :::
 144
 145 You can override the default GSettings values using the
 146 [](#opt-services.xserver.desktopManager.gnome.extraGSettingsOverrides) option.
 147
 148 Take note that whatever packages you want to override GSettings for, you need to add them to
 149 [](#opt-services.xserver.desktopManager.gnome.extraGSettingsOverridePackages).
 150
 151 You can use `dconf-editor` tool to explore which GSettings you can set.
 152
 153 ### Example {#sec-gnome-gsettings-overrides-example}
 154
 155 ```nix
 156 {
 157   services.xserver.desktopManager.gnome = {
 158     extraGSettingsOverrides = ''
 159       # Change default background
 160       [org.gnome.desktop.background]
 161       picture-uri='file://${pkgs.nixos-artwork.wallpapers.mosaic-blue.gnomeFilePath}'
 162
 163       # Favorite apps in gnome-shell
 164       [org.gnome.shell]
 165       favorite-apps=['org.gnome.Console.desktop', 'org.gnome.Nautilus.desktop']
 166     '';
 167
 168     extraGSettingsOverridePackages = [
 169       pkgs.gsettings-desktop-schemas # for org.gnome.desktop
 170       pkgs.gnome-shell # for org.gnome.shell
 171     ];
 172   };
 173 }
 174 ```
 175
 176 ## Frequently Asked Questions {#sec-gnome-faq}
 177
 178 ### Can I use LightDM with GNOME? {#sec-gnome-faq-can-i-use-lightdm-with-gnome}
 179
 180 Yes you can, and any other display-manager in NixOS.
 181
 182 However, it doesn’t work correctly for the Wayland session of GNOME Shell yet, and
 183 won’t be able to lock your screen.
 184
 185 See [this issue.](https://github.com/NixOS/nixpkgs/issues/56342)