nixos/modules/services/x11/display-managers/lightdm-greeters/tiny.nix

   1 { config, lib, pkgs, ... }:
   2
   3 with lib;
   4
   5 let
   6
   7   dmcfg = config.services.xserver.displayManager;
   8   ldmcfg = dmcfg.lightdm;
   9   cfg = ldmcfg.greeters.tiny;
  10
  11 in
  12 {
  13   options = {
  14
  15     services.xserver.displayManager.lightdm.greeters.tiny = {
  16
  17       enable = mkOption {
  18         type = types.bool;
  19         default = false;
  20         description = ''
  21           Whether to enable lightdm-tiny-greeter as the lightdm greeter.
  22
  23           Note that this greeter starts only the default X session.
  24           You can configure the default X session using
  25           [](#opt-services.displayManager.defaultSession).
  26         '';
  27       };
  28
  29       label = {
  30         user = mkOption {
  31           type = types.str;
  32           default = "Username";
  33           description = ''
  34             The string to represent the user_text label.
  35           '';
  36         };
  37
  38         pass = mkOption {
  39           type = types.str;
  40           default = "Password";
  41           description = ''
  42             The string to represent the pass_text label.
  43           '';
  44         };
  45       };
  46
  47
  48       extraConfig = mkOption {
  49         type = types.lines;
  50         default = "";
  51         description = ''
  52           Section to describe style and ui.
  53         '';
  54       };
  55
  56     };
  57
  58   };
  59
  60   config = mkIf (ldmcfg.enable && cfg.enable) {
  61
  62     services.xserver.displayManager.lightdm.greeters.gtk.enable = false;
  63
  64     services.xserver.displayManager.lightdm.greeter =
  65     let
  66       configHeader = ''
  67         #include <gtk/gtk.h>
  68         static const char *user_text = "${cfg.label.user}";
  69         static const char *pass_text = "${cfg.label.pass}";
  70         static const char *session = "${dmcfg.defaultSession}";
  71       '';
  72       config = optionalString (cfg.extraConfig != "") (configHeader + cfg.extraConfig);
  73       package = pkgs.lightdm-tiny-greeter.override { conf = config; };
  74     in
  75       mkDefault {
  76         package = package.xgreeters;
  77         name = "lightdm-tiny-greeter";
  78       };
  79
  80     assertions = [
  81       {
  82         assertion = dmcfg.defaultSession != null;
  83         message = ''
  84           Please set: services.displayManager.defaultSession
  85         '';
  86       }
  87     ];
  88
  89   };
  90 }