nixos/modules/system/boot/unl0kr.nix

   1 {
   2   config,
   3   lib,
   4   pkgs,
   5   ...
   6 }:
   7
   8 let
   9   cfg = config.boot.initrd.unl0kr;
  10   settingsFormat = pkgs.formats.ini { };
  11 in
  12 {
  13   options.boot.initrd.unl0kr = {
  14     enable = lib.mkEnableOption "unl0kr in initrd" // {
  15       description = ''Whether to enable the unl0kr on-screen keyboard in initrd to unlock LUKS.'';
  16     };
  17
  18     allowVendorDrivers = lib.mkEnableOption "load optional drivers" // {
  19       description = ''Whether to load additional drivers for certain vendors (I.E: Wacom, Intel, etc.)'';
  20     };
  21
  22     settings = lib.mkOption {
  23       description = ''
  24         Configuration for `unl0kr`.
  25
  26         See `unl0kr.conf(5)` for supported values.
  27
  28         Alternatively, visit `https://gitlab.com/postmarketOS/buffybox/-/blob/unl0kr-2.0.0/unl0kr.conf`
  29       '';
  30
  31       example = lib.literalExpression ''
  32         {
  33             general.animations = true;
  34             theme = {
  35                   default = "pmos-dark";
  36                   alternate = "pmos-light";
  37             };
  38         }
  39       '';
  40       default = { };
  41       type = lib.types.submodule { freeformType = settingsFormat.type; };
  42     };
  43   };
  44
  45   config = lib.mkIf cfg.enable {
  46     meta.maintainers = with lib.maintainers; [ hustlerone ];
  47     assertions = [
  48       {
  49         assertion = cfg.enable -> config.boot.initrd.systemd.enable;
  50         message = "boot.initrd.unl0kr is only supported with boot.initrd.systemd.";
  51       }
  52       {
  53         assertion = !config.boot.plymouth.enable;
  54         message = "unl0kr will not work if plymouth is enabled.";
  55       }
  56       {
  57         assertion = !config.hardware.amdgpu.initrd.enable;
  58         message = "unl0kr has issues with video drivers that are loaded on stage 1.";
  59       }
  60     ];
  61
  62     boot.initrd.availableKernelModules =
  63       lib.optionals cfg.enable [
  64         "hid-multitouch"
  65         "hid-generic"
  66         "usbhid"
  67
  68         "i2c-designware-core"
  69         "i2c-designware-platform"
  70         "i2c-hid-acpi"
  71
  72         "usbtouchscreen"
  73         "evdev"
  74       ]
  75       ++ lib.optionals cfg.allowVendorDrivers [
  76         "intel_lpss_pci"
  77         "elo"
  78         "wacom"
  79       ];
  80
  81     boot.initrd.systemd = {
  82       contents."/etc/unl0kr.conf".source = settingsFormat.generate "unl0kr.conf" cfg.settings;
  83       storePaths = with pkgs; [
  84         "${pkgs.gnugrep}/bin/grep"
  85         libinput
  86         xkeyboard_config
  87         "${config.boot.initrd.systemd.package}/lib/systemd/systemd-reply-password"
  88         "${pkgs.unl0kr}/bin/unl0kr"
  89       ];
  90       services = {
  91         unl0kr-ask-password = {
  92           description = "Forward Password Requests to unl0kr";
  93           conflicts = [
  94             "emergency.service"
  95             "initrd-switch-root.target"
  96             "shutdown.target"
  97           ];
  98           unitConfig.DefaultDependencies = false;
  99           after = [
 100             "systemd-vconsole-setup.service"
 101             "udev.service"
 102           ];
 103           before = [ "shutdown.target" ];
 104           script = ''
 105             # This script acts as a Password Agent: https://systemd.io/PASSWORD_AGENTS/
 106
 107             DIR=/run/systemd/ask-password/
 108             # If a user has multiple encrypted disks, the requests might come in different times,
 109             # so make sure to answer as many requests as we can. Once boot succeeds, other
 110             # password agents will be responsible for watching for requests.
 111             while [ -d $DIR ] && [ "$(ls -A $DIR/ask.*)" ];
 112             do
 113               for file in `ls $DIR/ask.*`; do
 114                 socket="$(cat "$file" | ${pkgs.gnugrep}/bin/grep "Socket=" | cut -d= -f2)"
 115                 ${pkgs.unl0kr}/bin/unl0kr -v -C "/etc/unl0kr.conf" | ${config.boot.initrd.systemd.package}/lib/systemd/systemd-reply-password 1 "$socket"
 116               done
 117             done
 118           '';
 119         };
 120       };
 121
 122       paths = {
 123         unl0kr-ask-password = {
 124           description = "Forward Password Requests to unl0kr";
 125           conflicts = [
 126             "emergency.service"
 127             "initrd-switch-root.target"
 128             "shutdown.target"
 129           ];
 130           unitConfig.DefaultDependencies = false;
 131           before = [
 132             "shutdown.target"
 133             "paths.target"
 134             "cryptsetup.target"
 135           ];
 136           wantedBy = [ "sysinit.target" ];
 137           pathConfig = {
 138             DirectoryNotEmpty = "/run/systemd/ask-password";
 139             MakeDirectory = true;
 140           };
 141         };
 142       };
 143     };
 144   };
 145 }