nixos/modules/virtualisation/lxc-image-metadata.nix

   1 { lib, config, pkgs, ... }:
   2
   3 let
   4   templateSubmodule = {...}: {
   5     options = {
   6       enable = lib.mkEnableOption "this template";
   7
   8       target = lib.mkOption {
   9         description = "Path in the container";
  10         type = lib.types.path;
  11       };
  12       template = lib.mkOption {
  13         description = ".tpl file for rendering the target";
  14         type = lib.types.path;
  15       };
  16       when = lib.mkOption {
  17         description = "Events which trigger a rewrite (create, copy)";
  18         type = lib.types.listOf (lib.types.str);
  19       };
  20       properties = lib.mkOption {
  21         description = "Additional properties";
  22         type = lib.types.attrs;
  23         default = {};
  24       };
  25     };
  26   };
  27
  28   toYAML = name: data: pkgs.writeText name (lib.generators.toYAML {} data);
  29
  30   cfg = config.virtualisation.lxc;
  31   templates = if cfg.templates != {} then let
  32     list = lib.mapAttrsToList (name: value: { inherit name; } // value)
  33       (lib.filterAttrs (name: value: value.enable) cfg.templates);
  34   in
  35     {
  36       files = map (tpl: {
  37         source = tpl.template;
  38         target = "/templates/${tpl.name}.tpl";
  39       }) list;
  40       properties = lib.listToAttrs (map (tpl: lib.nameValuePair tpl.target {
  41         when = tpl.when;
  42         template = "${tpl.name}.tpl";
  43         properties = tpl.properties;
  44       }) list);
  45     }
  46   else { files = []; properties = {}; };
  47
  48 in {
  49   meta = {
  50     maintainers = lib.teams.lxc.members;
  51   };
  52
  53   options = {
  54     virtualisation.lxc = {
  55       templates = lib.mkOption {
  56         description = "Templates for LXD";
  57         type = lib.types.attrsOf (lib.types.submodule templateSubmodule);
  58         default = {};
  59         example = lib.literalExpression ''
  60           {
  61             # create /etc/hostname on container creation
  62             "hostname" = {
  63               enable = true;
  64               target = "/etc/hostname";
  65               template = builtins.writeFile "hostname.tpl" "{{ container.name }}";
  66               when = [ "create" ];
  67             };
  68             # create /etc/nixos/hostname.nix with a configuration for keeping the hostname applied
  69             "hostname-nix" = {
  70               enable = true;
  71               target = "/etc/nixos/hostname.nix";
  72               template = builtins.writeFile "hostname-nix.tpl" "{ ... }: { networking.hostName = "{{ container.name }}"; }";
  73               # copy keeps the file updated when the container is changed
  74               when = [ "create" "copy" ];
  75             };
  76             # copy allow the user to specify a custom configuration.nix
  77             "configuration-nix" = {
  78               enable = true;
  79               target = "/etc/nixos/configuration.nix";
  80               template = builtins.writeFile "configuration-nix" "{{ config_get(\"user.user-data\", properties.default) }}";
  81               when = [ "create" ];
  82             };
  83           };
  84         '';
  85       };
  86     };
  87   };
  88
  89   config = {
  90     system.build.metadata = pkgs.callPackage ../../lib/make-system-tarball.nix {
  91       contents = [
  92         {
  93           source = toYAML "metadata.yaml" {
  94             architecture = builtins.elemAt (builtins.match "^([a-z0-9_]+).+" (toString pkgs.stdenv.hostPlatform.system)) 0;
  95             creation_date = 1;
  96             properties = {
  97               description = "${config.system.nixos.distroName} ${config.system.nixos.codeName} ${config.system.nixos.label} ${pkgs.stdenv.hostPlatform.system}";
  98               os = "${config.system.nixos.distroId}";
  99               release = "${config.system.nixos.codeName}";
 100             };
 101             templates = templates.properties;
 102           };
 103           target = "/metadata.yaml";
 104         }
 105       ] ++ templates.files;
 106     };
 107   };
 108 }