nixos/modules/virtualisation/virtualbox-image.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3
   4   cfg = config.virtualbox;
   5
   6 in {
   7
   8   options = {
   9     virtualbox = {
  10       baseImageSize = lib.mkOption {
  11         type = with lib.types; either (enum [ "auto" ]) int;
  12         default = "auto";
  13         example = 50 * 1024;
  14         description = ''
  15           The size of the VirtualBox base image in MiB.
  16         '';
  17       };
  18       baseImageFreeSpace = lib.mkOption {
  19         type = with lib.types; int;
  20         default = 30 * 1024;
  21         description = ''
  22           Free space in the VirtualBox base image in MiB.
  23         '';
  24       };
  25       memorySize = lib.mkOption {
  26         type = lib.types.int;
  27         default = 1536;
  28         description = ''
  29           The amount of RAM the VirtualBox appliance can use in MiB.
  30         '';
  31       };
  32       vmDerivationName = lib.mkOption {
  33         type = lib.types.str;
  34         default = "nixos-ova-${config.system.nixos.label}-${pkgs.stdenv.hostPlatform.system}";
  35         description = ''
  36           The name of the derivation for the VirtualBox appliance.
  37         '';
  38       };
  39       vmName = lib.mkOption {
  40         type = lib.types.str;
  41         default = "${config.system.nixos.distroName} ${config.system.nixos.label} (${pkgs.stdenv.hostPlatform.system})";
  42         description = ''
  43           The name of the VirtualBox appliance.
  44         '';
  45       };
  46       vmFileName = lib.mkOption {
  47         type = lib.types.str;
  48         default = "nixos-${config.system.nixos.label}-${pkgs.stdenv.hostPlatform.system}.ova";
  49         description = ''
  50           The file name of the VirtualBox appliance.
  51         '';
  52       };
  53       params = lib.mkOption {
  54         type = with lib.types; attrsOf (oneOf [ str int bool (listOf str) ]);
  55         example = {
  56           audio = "alsa";
  57           rtcuseutc = "on";
  58           usb = "off";
  59         };
  60         description = ''
  61           Parameters passed to the Virtualbox appliance.
  62
  63           Run `VBoxManage modifyvm --help` to see more options.
  64         '';
  65       };
  66       exportParams = lib.mkOption {
  67         type = with lib.types; listOf (oneOf [ str int bool (listOf str) ]);
  68         example = [
  69           "--vsys" "0" "--vendor" "ACME Inc."
  70         ];
  71         default = [];
  72         description = ''
  73           Parameters passed to the Virtualbox export command.
  74
  75           Run `VBoxManage export --help` to see more options.
  76         '';
  77       };
  78       extraDisk = lib.mkOption {
  79         description = ''
  80           Optional extra disk/hdd configuration.
  81           The disk will be an 'ext4' partition on a separate file.
  82         '';
  83         default = null;
  84         example = {
  85           label = "storage";
  86           mountPoint = "/home/demo/storage";
  87           size = 100 * 1024;
  88         };
  89         type = lib.types.nullOr (lib.types.submodule {
  90           options = {
  91             size = lib.mkOption {
  92               type = lib.types.int;
  93               description = "Size in MiB";
  94             };
  95             label = lib.mkOption {
  96               type = lib.types.str;
  97               default = "vm-extra-storage";
  98               description = "Label for the disk partition";
  99             };
 100             mountPoint = lib.mkOption {
 101               type = lib.types.str;
 102               description = "Path where to mount this disk.";
 103             };
 104           };
 105         });
 106       };
 107       postExportCommands = lib.mkOption {
 108         type = lib.types.lines;
 109         default = "";
 110         example = ''
 111           ${pkgs.cot}/bin/cot edit-hardware "$fn" \
 112             -v vmx-14 \
 113             --nics 2 \
 114             --nic-types VMXNET3 \
 115             --nic-names 'Nic name' \
 116             --nic-networks 'Nic match' \
 117             --network-descriptions 'Nic description' \
 118             --scsi-subtypes VirtualSCSI
 119         '';
 120         description = ''
 121           Extra commands to run after exporting the OVA to `$fn`.
 122         '';
 123       };
 124       storageController = lib.mkOption {
 125         type = with lib.types; attrsOf (oneOf [ str int bool (listOf str) ]);
 126         example = {
 127           name = "SCSI";
 128           add = "scsi";
 129           portcount = 16;
 130           bootable = "on";
 131           hostiocache = "on";
 132         };
 133         default = {
 134           name = "SATA";
 135           add = "sata";
 136           portcount = 4;
 137           bootable = "on";
 138           hostiocache = "on";
 139         };
 140         description = ''
 141           Parameters passed to the VirtualBox appliance. Must have at least
 142           `name`.
 143
 144           Run `VBoxManage storagectl --help` to see more options.
 145         '';
 146       };
 147     };
 148   };
 149
 150   config = {
 151
 152     virtualbox.params = lib.mkMerge [
 153       (lib.mapAttrs (name: lib.mkDefault) {
 154         acpi = "on";
 155         vram = 32;
 156         nictype1 = "virtio";
 157         nic1 = "nat";
 158         audiocontroller = "ac97";
 159         audio = "alsa";
 160         audioout = "on";
 161         graphicscontroller = "vmsvga";
 162         rtcuseutc = "on";
 163         usb = "on";
 164         usbehci = "on";
 165         mouse = "usbtablet";
 166       })
 167       (lib.mkIf (pkgs.stdenv.hostPlatform.system == "i686-linux") { pae = "on"; })
 168     ];
 169
 170     system.build.virtualBoxOVA = import ../../lib/make-disk-image.nix {
 171       name = cfg.vmDerivationName;
 172
 173       inherit pkgs lib config;
 174       partitionTableType = "legacy";
 175       diskSize = cfg.baseImageSize;
 176       additionalSpace = "${toString cfg.baseImageFreeSpace}M";
 177
 178       postVM =
 179         ''
 180           export HOME=$PWD
 181           export PATH=${pkgs.virtualbox}/bin:$PATH
 182
 183           echo "converting image to VirtualBox format..."
 184           VBoxManage convertfromraw $diskImage disk.vdi
 185
 186           ${lib.optionalString (cfg.extraDisk != null) ''
 187             echo "creating extra disk: data-disk.raw"
 188             dataDiskImage=data-disk.raw
 189             truncate -s ${toString cfg.extraDisk.size}M $dataDiskImage
 190
 191             parted --script $dataDiskImage -- \
 192               mklabel msdos \
 193               mkpart primary ext4 1MiB -1
 194             eval $(partx $dataDiskImage -o START,SECTORS --nr 1 --pairs)
 195             mkfs.ext4 -F -L ${cfg.extraDisk.label} $dataDiskImage -E offset=$(sectorsToBytes $START) $(sectorsToKilobytes $SECTORS)K
 196             echo "creating extra disk: data-disk.vdi"
 197             VBoxManage convertfromraw $dataDiskImage data-disk.vdi
 198           ''}
 199
 200           echo "creating VirtualBox VM..."
 201           vmName="${cfg.vmName}";
 202           VBoxManage createvm --name "$vmName" --register \
 203             --ostype ${if pkgs.stdenv.hostPlatform.system == "x86_64-linux" then "Linux26_64" else "Linux26"}
 204           VBoxManage modifyvm "$vmName" \
 205             --memory ${toString cfg.memorySize} \
 206             ${lib.cli.toGNUCommandLineShell { } cfg.params}
 207           VBoxManage storagectl "$vmName" ${lib.cli.toGNUCommandLineShell { } cfg.storageController}
 208           VBoxManage storageattach "$vmName" --storagectl ${cfg.storageController.name} --port 0 --device 0 --type hdd \
 209             --medium disk.vdi
 210           ${lib.optionalString (cfg.extraDisk != null) ''
 211             VBoxManage storageattach "$vmName" --storagectl ${cfg.storageController.name} --port 1 --device 0 --type hdd \
 212             --medium data-disk.vdi
 213           ''}
 214
 215           echo "exporting VirtualBox VM..."
 216           mkdir -p $out
 217           fn="$out/${cfg.vmFileName}"
 218           VBoxManage export "$vmName" --output "$fn" --options manifest ${lib.escapeShellArgs cfg.exportParams}
 219           ${cfg.postExportCommands}
 220
 221           rm -v $diskImage
 222
 223           mkdir -p $out/nix-support
 224           echo "file ova $fn" >> $out/nix-support/hydra-build-products
 225         '';
 226     };
 227
 228     fileSystems = {
 229       "/" = {
 230         device = "/dev/disk/by-label/nixos";
 231         autoResize = true;
 232         fsType = "ext4";
 233       };
 234     } // (lib.optionalAttrs (cfg.extraDisk != null) {
 235       ${cfg.extraDisk.mountPoint} = {
 236         device = "/dev/disk/by-label/" + cfg.extraDisk.label;
 237         autoResize = true;
 238         fsType = "ext4";
 239       };
 240     });
 241
 242     boot.growPartition = true;
 243     boot.loader.grub.device = "/dev/sda";
 244
 245     swapDevices = [{
 246       device = "/var/swap";
 247       size = 2048;
 248     }];
 249
 250     virtualisation.virtualbox.guest.enable = true;
 251
 252   };
 253 }