nixos/tests/incus/incusd-options.nix

   1 # this is a set of tests for non-default options. typically the default options
   2 # will be handled by the other tests
   3 import ../make-test-python.nix (
   4   {
   5     pkgs,
   6     lib,
   7     incus ? pkgs.incus-lts,
   8     ...
   9   }:
  10
  11   let
  12     releases = import ../../release.nix {
  13       configuration = {
  14         # Building documentation makes the test unnecessarily take a longer time:
  15         documentation.enable = lib.mkForce false;
  16       };
  17     };
  18
  19     container-image-metadata = "${
  20       releases.incusContainerMeta.${pkgs.stdenv.hostPlatform.system}
  21     }/tarball/nixos-system-${pkgs.stdenv.hostPlatform.system}.tar.xz";
  22     container-image-rootfs = "${
  23       releases.incusContainerImage.${pkgs.stdenv.hostPlatform.system}
  24     }/nixos-lxc-image-${pkgs.stdenv.hostPlatform.system}.squashfs";
  25   in
  26   {
  27     name = "incusd-options";
  28
  29     meta = {
  30       maintainers = lib.teams.lxc.members;
  31     };
  32
  33     nodes.machine = {
  34       virtualisation = {
  35         cores = 2;
  36         memorySize = 1024;
  37         diskSize = 4096;
  38
  39         incus = {
  40           enable = true;
  41           package = incus;
  42           softDaemonRestart = false;
  43
  44           preseed = {
  45             networks = [
  46               {
  47                 name = "nixostestbr0";
  48                 type = "bridge";
  49                 config = {
  50                   "ipv4.address" = "10.0.100.1/24";
  51                   "ipv4.nat" = "true";
  52                 };
  53               }
  54             ];
  55             profiles = [
  56               {
  57                 name = "default";
  58                 devices = {
  59                   eth0 = {
  60                     name = "eth0";
  61                     network = "nixostestbr0";
  62                     type = "nic";
  63                   };
  64                   root = {
  65                     path = "/";
  66                     pool = "nixostest_pool";
  67                     size = "35GiB";
  68                     type = "disk";
  69                   };
  70                 };
  71               }
  72             ];
  73             storage_pools = [
  74               {
  75                 name = "nixostest_pool";
  76                 driver = "dir";
  77               }
  78             ];
  79           };
  80         };
  81       };
  82       networking.nftables.enable = true;
  83     };
  84
  85     testScript = ''
  86       def instance_is_up(_) -> bool:
  87           status, _ = machine.execute("incus exec container --disable-stdin --force-interactive /run/current-system/sw/bin/systemctl -- is-system-running")
  88           return status == 0
  89
  90       machine.wait_for_unit("incus.service")
  91       machine.wait_for_unit("incus-preseed.service")
  92
  93       with subtest("Container image can be imported"):
  94           machine.succeed("incus image import ${container-image-metadata} ${container-image-rootfs} --alias nixos")
  95
  96       with subtest("Container can be launched and managed"):
  97           machine.succeed("incus launch nixos container")
  98           with machine.nested("Waiting for instance to start and be usable"):
  99             retry(instance_is_up)
 100           machine.succeed("echo true | incus exec container /run/current-system/sw/bin/bash -")
 101
 102       with subtest("Verify preseed resources created"):
 103           machine.succeed("incus profile show default")
 104           machine.succeed("incus network info nixostestbr0")
 105           machine.succeed("incus storage show nixostest_pool")
 106
 107       with subtest("Instance is stopped when softDaemonRestart is disabled and services is stopped"):
 108           pid = machine.succeed("incus info container | grep 'PID'").split(":")[1].strip()
 109           machine.succeed(f"ps {pid}")
 110           machine.succeed("systemctl stop incus")
 111           machine.fail(f"ps {pid}")
 112     '';
 113   }
 114 )