nixos/tests/systemd-initrd-swraid.nix

   1 import ./make-test-python.nix ({ lib, pkgs, ... }: {
   2   name = "systemd-initrd-swraid";
   3
   4   nodes.machine = { pkgs, ... }: {
   5     # Use systemd-boot
   6     virtualisation = {
   7       emptyDiskImages = [ 512 512 ];
   8       useBootLoader = true;
   9       # Booting off the RAID requires an available init script
  10       mountHostNixStore = true;
  11       useEFIBoot = true;
  12     };
  13     boot.loader.systemd-boot.enable = true;
  14     boot.loader.efi.canTouchEfiVariables = true;
  15
  16     environment.systemPackages = with pkgs; [ mdadm e2fsprogs ]; # for mdadm and mkfs.ext4
  17     boot.swraid = {
  18       enable = true;
  19       mdadmConf = ''
  20         ARRAY /dev/md0 devices=/dev/vdb,/dev/vdc
  21       '';
  22     };
  23     environment.etc."mdadm.conf".text = ''
  24       MAILADDR test@example.com
  25     '';
  26     boot.initrd = {
  27       systemd = {
  28         enable = true;
  29         emergencyAccess = true;
  30       };
  31       kernelModules = [ "raid0" ];
  32     };
  33
  34     specialisation.boot-swraid.configuration.virtualisation.rootDevice = "/dev/disk/by-label/testraid";
  35     # This protects against a regression. We do not have to switch to it.
  36     # It's sufficient to trigger its evaluation.
  37     specialisation.build-old-initrd.configuration.boot.initrd.systemd.enable = lib.mkForce false;
  38   };
  39
  40   testScript = ''
  41     # Create RAID
  42     machine.succeed("mdadm --create --force /dev/md0 -n 2 --level=raid1 /dev/vdb /dev/vdc --metadata=0.90")
  43     machine.succeed("mkfs.ext4 -L testraid /dev/md0")
  44     machine.succeed("mkdir -p /mnt && mount /dev/md0 /mnt && echo hello > /mnt/test && umount /mnt")
  45
  46     # Boot from the RAID
  47     machine.succeed("bootctl set-default nixos-generation-1-specialisation-boot-swraid.conf")
  48     machine.succeed("sync")
  49     machine.crash()
  50     machine.wait_for_unit("multi-user.target")
  51
  52     # Ensure we have successfully booted from the RAID
  53     assert "(initrd)" in machine.succeed("systemd-analyze")  # booted with systemd in stage 1
  54     assert "/dev/md0 on / type ext4" in machine.succeed("mount")
  55     assert "hello" in machine.succeed("cat /test")
  56     assert "md0" in machine.succeed("cat /proc/mdstat")
  57
  58     expected_config = """MAILADDR test@example.com
  59
  60     ARRAY /dev/md0 devices=/dev/vdb,/dev/vdc
  61     """
  62     got_config = machine.execute("cat /etc/mdadm.conf")[1]
  63     assert expected_config == got_config, repr((expected_config, got_config))
  64     machine.wait_for_unit("mdmonitor.service")
  65   '';
  66 })