nixos/tests/systemd-networkd-ipv6-prefix-delegation.nix

   1 # This test verifies that we can request and assign IPv6 prefixes from upstream
   2 # (e.g. ISP) routers.
   3 # The setup consists of three VMs. One for the ISP, as your residential router
   4 # and the third as a client machine in the residential network.
   5 #
   6 # There are two VLANs in this test:
   7 # - VLAN 1 is the connection between the ISP and the router
   8 # - VLAN 2 is the connection between the router and the client
   9
  10 import ./make-test-python.nix ({ pkgs, lib, ... }: {
  11   name = "systemd-networkd-ipv6-prefix-delegation";
  12   meta = with lib.maintainers; {
  13     maintainers = [ andir hexa ];
  14   };
  15   nodes = {
  16
  17     # The ISP's routers job is to delegate IPv6 prefixes via DHCPv6. Like with
  18     # regular IPv6 auto-configuration it will also emit IPv6 router
  19     # advertisements (RAs). Those RA's will not carry a prefix but in contrast
  20     # just set the "Other" flag to indicate to the receiving nodes that they
  21     # should attempt DHCPv6.
  22     #
  23     # Note: On the ISPs device we don't really care if we are using networkd in
  24     # this example. That being said we can't use it (yet) as networkd doesn't
  25     # implement the serving side of DHCPv6. We will use ISC Kea for that task.
  26     isp = { lib, pkgs, ... }: {
  27       virtualisation.vlans = [ 1 ];
  28       networking = {
  29         useDHCP = false;
  30         firewall.enable = false;
  31         interfaces.eth1 = lib.mkForce {}; # Don't use scripted networking
  32       };
  33
  34       systemd.network = {
  35         enable = true;
  36
  37         networks = {
  38           "eth1" = {
  39             matchConfig.Name = "eth1";
  40             address = [
  41               "2001:DB8::1/64"
  42             ];
  43             networkConfig.IPv4Forwarding = true;
  44             networkConfig.IPv6Forwarding = true;
  45           };
  46         };
  47       };
  48
  49       # Since we want to program the routes that we delegate to the "customer"
  50       # into our routing table we must provide kea with the required capability.
  51       systemd.services.kea-dhcp6-server.serviceConfig = {
  52         AmbientCapabilities = [ "CAP_NET_ADMIN" ];
  53         CapabilityBoundingSet = [ "CAP_NET_ADMIN" ];
  54       };
  55
  56       services = {
  57         # Configure the DHCPv6 server to hand out both IA_NA and IA_PD.
  58         #
  59         # We will hand out /48 prefixes from the subnet 2001:DB8:F000::/36.
  60         # That gives us ~8k prefixes. That should be enough for this test.
  61         #
  62         # Since (usually) you will not receive a prefix with the router
  63         # advertisements we also hand out /128 leases from the range
  64         # 2001:DB8:0000:0000:FFFF::/112.
  65         kea.dhcp6 = {
  66           enable = true;
  67           settings = {
  68             interfaces-config.interfaces = [ "eth1" ];
  69             subnet6 = [ {
  70               id = 1;
  71               interface = "eth1";
  72               subnet = "2001:DB8::/32";
  73               pd-pools = [ {
  74                 prefix = "2001:DB8:1000::";
  75                 prefix-len = 36;
  76                 delegated-len = 48;
  77               } ];
  78               pools = [ {
  79                 pool = "2001:DB8:0000:0000::-2001:DB8:0FFF:FFFF::FFFF";
  80               } ];
  81             } ];
  82
  83             # This is the glue between Kea and the Kernel FIB. DHCPv6
  84             # rightfully has no concept of setting up a route in your
  85             # FIB. This step really depends on your setup.
  86             #
  87             # In a production environment your DHCPv6 server is likely
  88             # not the router. You might want to consider BGP, NETCONF
  89             # calls, … in those cases.
  90             #
  91             # In this example we use the run script hook, that lets use
  92             # execute anything and passes information via the environment.
  93             # https://kea.readthedocs.io/en/kea-2.2.0/arm/hooks.html#run-script-run-script-support-for-external-hook-scripts
  94             hooks-libraries = [ {
  95               library = "${pkgs.kea}/lib/kea/hooks/libdhcp_run_script.so";
  96               parameters = {
  97                 name = pkgs.writeShellScript "kea-run-hooks" ''
  98                   export PATH="${lib.makeBinPath (with pkgs; [ coreutils iproute2 ])}"
  99
 100                   set -euxo pipefail
 101
 102                   leases6_committed() {
 103                     for i in $(seq $LEASES6_SIZE); do
 104                       idx=$((i-1))
 105                       prefix_var="LEASES6_AT''${idx}_ADDRESS"
 106                       plen_var="LEASES6_AT''${idx}_PREFIX_LEN"
 107
 108                       ip -6 route replace ''${!prefix_var}/''${!plen_var} via $QUERY6_REMOTE_ADDR dev $QUERY6_IFACE_NAME
 109                     done
 110                   }
 111
 112                   unknown_handler() {
 113                     echo "Unhandled function call ''${*}"
 114                     exit 123
 115                   }
 116
 117                   case "$1" in
 118                       "leases6_committed")
 119                           leases6_committed
 120                           ;;
 121                       *)
 122                           unknown_handler "''${@}"
 123                           ;;
 124                   esac
 125                 '';
 126                 sync = false;
 127               };
 128             } ];
 129           };
 130         };
 131
 132         # Finally we have to set up the router advertisements. While we could be
 133         # using networkd or bird for this task `radvd` is probably the most
 134         # venerable of them all. It was made explicitly for this purpose and
 135         # the configuration is much more straightforward than what networkd
 136         # requires.
 137         # As outlined above we will have to set the `Managed` flag as otherwise
 138         # the clients will not know if they should do DHCPv6. (Some do
 139         # anyway/always)
 140         radvd = {
 141           enable = true;
 142           config = ''
 143             interface eth1 {
 144               AdvSendAdvert on;
 145               AdvManagedFlag on;
 146               AdvOtherConfigFlag off; # we don't really have DNS or NTP or anything like that to distribute
 147               prefix ::/64 {
 148                 AdvOnLink on;
 149                 AdvAutonomous on;
 150               };
 151             };
 152           '';
 153         };
 154
 155       };
 156     };
 157
 158     # This will be our (residential) router that receives the IPv6 prefix (IA_PD)
 159     # and /128 (IA_NA) allocation.
 160     #
 161     # Here we will actually start using networkd.
 162     router = {
 163       virtualisation.vlans = [ 1 2 ];
 164       systemd.services.systemd-networkd.environment.SYSTEMD_LOG_LEVEL = "debug";
 165
 166       boot.kernel.sysctl = {
 167         # we want to forward packets from the ISP to the client and back.
 168         "net.ipv6.conf.all.forwarding" = 1;
 169       };
 170
 171       networking = {
 172         useNetworkd = true;
 173         useDHCP = false;
 174         # Consider enabling this in production and generating firewall rules
 175         # for fowarding/input from the configured interfaces so you do not have
 176         # to manage multiple places
 177         firewall.enable = false;
 178         interfaces.eth1.ipv6.addresses = lib.mkForce [ ];
 179       };
 180
 181       systemd.network = {
 182         networks = {
 183           # systemd-networkd will load the first network unit file
 184           # that matches, ordered lexiographically by filename.
 185           # /etc/systemd/network/{40-eth1,99-main}.network already
 186           # exists. This network unit must be loaded for the test,
 187           # however, hence why this network is named such.
 188
 189           # Configuration of the interface to the ISP.
 190           # We must request accept RAs and request the PD prefix.
 191           "01-eth1" = {
 192             name = "eth1";
 193             networkConfig = {
 194               Description = "ISP interface";
 195               IPv6AcceptRA = true;
 196               #DHCP = false; # no need for legacy IP
 197             };
 198             linkConfig = {
 199               # We care about this interface when talking about being "online".
 200               # If this interface is in the `routable` state we can reach
 201               # others and they should be able to reach us.
 202               RequiredForOnline = "routable";
 203             };
 204             # This configures the DHCPv6 client part towards the ISPs DHCPv6 server.
 205             dhcpV6Config = {
 206               # We have to include a request for a prefix in our DHCPv6 client
 207               # request packets.
 208               # Otherwise the upstream DHCPv6 server wouldn't know if we want a
 209               # prefix or not.  Note: On some installation it makes sense to
 210               # always force that option on the DHPCv6 server since there are
 211               # certain CPEs that are just not setting this field but happily
 212               # accept the delegated prefix.
 213               PrefixDelegationHint  = "::/48";
 214             };
 215             ipv6SendRAConfig = {
 216               # Let networkd know that we would very much like to use DHCPv6
 217               # to obtain the "managed" information. Not sure why they can't
 218               # just take that from the upstream RAs.
 219               Managed = true;
 220             };
 221           };
 222
 223           # Interface to the client. Here we should redistribute a /64 from
 224           # the prefix we received from the ISP.
 225           "01-eth2" = {
 226             name = "eth2";
 227             networkConfig = {
 228               Description = "Client interface";
 229               # The client shouldn't be allowed to send us RAs, that would be weird.
 230               IPv6AcceptRA = false;
 231
 232               # Delegate prefixes from the DHCPv6 PD pool.
 233               DHCPPrefixDelegation = true;
 234               IPv6SendRA = true;
 235             };
 236
 237             # In a production environment you should consider setting these as well:
 238             # ipv6SendRAConfig = {
 239               #EmitDNS = true;
 240               #EmitDomains = true;
 241               #DNS= = "fe80::1"; # or whatever "well known" IP your router will have on the inside.
 242             # };
 243
 244             # This adds a "random" ULA prefix to the interface that is being
 245             # advertised to the clients.
 246             # Not used in this test.
 247             # ipv6Prefixes = [
 248             #   {
 249             #     ipv6PrefixConfig = {
 250             #       AddressAutoconfiguration = true;
 251             #       PreferredLifetimeSec = 1800;
 252             #       ValidLifetimeSec = 1800;
 253             #     };
 254             #   }
 255             # ];
 256           };
 257
 258           # finally we are going to add a static IPv6 unique local address to
 259           # the "lo" interface.  This will serve as ICMPv6 echo target to
 260           # verify connectivity from the client to the router.
 261           "01-lo" = {
 262             name = "lo";
 263             addresses = [
 264               { Address = "FD42::1/128"; }
 265             ];
 266           };
 267         };
 268       };
 269     };
 270
 271     # This is the client behind the router. We should be receiving router
 272     # advertisements for both the ULA and the delegated prefix.
 273     # All we have to do is boot with the default (networkd) configuration.
 274     client = {
 275       virtualisation.vlans = [ 2 ];
 276       systemd.services.systemd-networkd.environment.SYSTEMD_LOG_LEVEL = "debug";
 277       networking = {
 278         useNetworkd = true;
 279         useDHCP = false;
 280         interfaces.eth1.ipv6.addresses = lib.mkForce [ ];
 281       };
 282     };
 283   };
 284
 285   testScript = ''
 286     # First start the router and wait for it it reach a state where we are
 287     # certain networkd is up and it is able to send out RAs
 288     router.start()
 289     router.wait_for_unit("systemd-networkd.service")
 290
 291     # After that we can boot the client and wait for the network online target.
 292     # Since we only care about IPv6 that should not involve waiting for legacy
 293     # IP leases.
 294     client.start()
 295     client.systemctl("start network-online.target")
 296     client.wait_for_unit("network-online.target")
 297
 298     # the static address on the router should not be reachable
 299     client.wait_until_succeeds("ping -6 -c 1 FD42::1")
 300
 301     # the global IP of the ISP router should still not be a reachable
 302     router.fail("ping -6 -c 1 2001:DB8::1")
 303
 304     # Once we have internal connectivity boot up the ISP
 305     isp.start()
 306
 307     # Since for the ISP "being online" should have no real meaning we just
 308     # wait for the target where all the units have been started.
 309     # It probably still takes a few more seconds for all the RA timers to be
 310     # fired etc..
 311     isp.wait_for_unit("multi-user.target")
 312
 313     # wait until the uplink interface has a good status
 314     router.systemctl("start network-online.target")
 315     router.wait_for_unit("network-online.target")
 316     router.wait_until_succeeds("ping -6 -c1 2001:DB8::1")
 317
 318     # shortly after that the client should have received it's global IPv6
 319     # address and thus be able to ping the ISP
 320     client.wait_until_succeeds("ping -6 -c1 2001:DB8::1")
 321
 322     # verify that we got a globally scoped address in eth1 from the
 323     # documentation prefix
 324     ip_output = client.succeed("ip --json -6 address show dev eth1")
 325
 326     import json
 327
 328     ip_json = json.loads(ip_output)[0]
 329     assert any(
 330         addr["local"].upper().startswith("2001:DB8:")
 331         for addr in ip_json["addr_info"]
 332         if addr["scope"] == "global"
 333     )
 334   '';
 335 })