pkgs/applications/blockchains/bitcoin-knots/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , fetchpatch2
   5 , autoreconfHook
   6 , pkg-config
   7 , util-linux
   8 , hexdump
   9 , autoSignDarwinBinariesHook
  10 , wrapQtAppsHook ? null
  11 , boost
  12 , libevent
  13 , miniupnpc
  14 , zeromq
  15 , zlib
  16 , db48
  17 , sqlite
  18 , qrencode
  19 , qtbase ? null
  20 , qttools ? null
  21 , python3
  22 , withGui
  23 , withWallet ? true
  24 }:
  25
  26 stdenv.mkDerivation rec {
  27   pname = if withGui then "bitcoin-knots" else "bitcoind-knots";
  28   version = "26.1.knots20240325";
  29
  30   src = fetchurl {
  31     url = "https://bitcoinknots.org/files/26.x/${version}/bitcoin-${version}.tar.gz";
  32     hash = "sha256-PqpePDna2gpCzF2K43N4h6cV5Y9w/e5ZcUvaNEaFaIk=";
  33   };
  34
  35   patches = [
  36     # upnp: add compatibility for miniupnpc 2.2.8
  37     (fetchpatch2 {
  38       url = "https://github.com/bitcoinknots/bitcoin/commit/643014424359a4783cf9c73bee3346ac2f04e713.patch?full_index=1";
  39       hash = "sha256-FdLoNH3+ZZTbqrwRvhbAeJuGz4SgnIvoWUBzRxjfzs8=";
  40     })
  41   ];
  42
  43   nativeBuildInputs =
  44     [ autoreconfHook pkg-config ]
  45     ++ lib.optionals stdenv.hostPlatform.isLinux [ util-linux ]
  46     ++ lib.optionals stdenv.hostPlatform.isDarwin [ hexdump ]
  47     ++ lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) [ autoSignDarwinBinariesHook ]
  48     ++ lib.optionals withGui [ wrapQtAppsHook ];
  49
  50   buildInputs = [ boost libevent miniupnpc zeromq zlib ]
  51     ++ lib.optionals withWallet [ sqlite ]
  52     ++ lib.optionals (withWallet && !stdenv.hostPlatform.isDarwin) [ db48 ]
  53     ++ lib.optionals withGui [ qrencode qtbase qttools ];
  54
  55   configureFlags = [
  56     "--with-boost-libdir=${boost.out}/lib"
  57     "--disable-bench"
  58   ] ++ lib.optionals (!doCheck) [
  59     "--disable-tests"
  60     "--disable-gui-tests"
  61   ] ++ lib.optionals (!withWallet) [
  62     "--disable-wallet"
  63   ] ++ lib.optionals withGui [
  64     "--with-gui=qt5"
  65     "--with-qt-bindir=${qtbase.dev}/bin:${qttools.dev}/bin"
  66   ];
  67
  68   nativeCheckInputs = [ python3 ];
  69
  70   doCheck = true;
  71
  72   checkFlags =
  73     [ "LC_ALL=en_US.UTF-8" ]
  74     # QT_PLUGIN_PATH needs to be set when executing QT, which is needed when testing Bitcoin's GUI.
  75     # See also https://github.com/NixOS/nixpkgs/issues/24256
  76     ++ lib.optional withGui "QT_PLUGIN_PATH=${qtbase}/${qtbase.qtPluginPrefix}";
  77
  78   enableParallelBuilding = true;
  79
  80   meta = with lib; {
  81     description = "Derivative of Bitcoin Core with a collection of improvements";
  82     homepage = "https://bitcoinknots.org/";
  83     changelog = "https://github.com/bitcoinknots/bitcoin/blob/v${version}/doc/release-notes.md";
  84     maintainers = with maintainers; [ prusnak mmahut ];
  85     license = licenses.mit;
  86     platforms = platforms.unix;
  87   };
  88 }