pkgs/by-name/al/alsa-firmware/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   buildPackages,
   5   autoreconfHook,
   6   fetchurl,
   7   fetchpatch,
   8 }:
   9
  10 stdenv.mkDerivation rec {
  11   pname = "alsa-firmware";
  12   version = "1.2.4";
  13
  14   src = fetchurl {
  15     url = "mirror://alsa/firmware/alsa-firmware-${version}.tar.bz2";
  16     hash = "sha256-tnttfQi8/CR+9v8KuIqZwYgwWjz1euLf0LzZpbNs1bs=";
  17   };
  18
  19   patches = [
  20     # fixes some includes / missing types on musl libc; should not make a difference for other platforms
  21     (fetchpatch {
  22       url = "https://raw.githubusercontent.com/void-linux/void-packages/ae690000017d5fd355ab397c49202426e3a01c11/srcpkgs/alsa-firmware/patches/musl.patch";
  23       hash = "sha256-4A+TBBvpz14NwMNewLc2LQL51hnz4EZlZ44rhnx5dnc=";
  24     })
  25   ];
  26
  27   nativeBuildInputs = [ autoreconfHook ];
  28
  29   configureFlags = [ "--with-hotplug-dir=$(out)/lib/firmware" ];
  30
  31   depsBuildBuild = lib.optional (
  32     stdenv.buildPlatform != stdenv.hostPlatform || stdenv.hostPlatform.isAarch64
  33   ) buildPackages.stdenv.cc;
  34
  35   dontStrip = true;
  36
  37   postInstall = ''
  38     # These are lifted from the Arch PKGBUILD
  39     # remove files which conflicts with linux-firmware
  40     rm -rf $out/lib/firmware/{ct{efx,speq}.bin,ess,korg,sb16,yamaha}
  41     # remove broken symlinks (broken upstream)
  42     rm -rf $out/lib/firmware/turtlebeach
  43     # remove empty dir
  44     rm -rf $out/bin
  45   '';
  46
  47   meta = with lib; {
  48     homepage = "http://www.alsa-project.org/";
  49     description = "Soundcard firmwares from the alsa project";
  50     license = licenses.gpl2Plus;
  51     platforms = platforms.linux;
  52     maintainers = with maintainers; [ l-as ];
  53   };
  54 }