pkgs/by-name/aw/aws-sso-cli/package.nix

   1 { buildGoModule
   2 , fetchFromGitHub
   3 , getent
   4 , lib
   5 , makeWrapper
   6 , stdenv
   7 , xdg-utils
   8 }:
   9 buildGoModule rec {
  10   pname = "aws-sso-cli";
  11   version = "1.17.0";
  12
  13   src = fetchFromGitHub {
  14     owner = "synfinatic";
  15     repo = pname;
  16     rev = "v${version}";
  17     hash = "sha256-VEI+vCNeNoFOE+2j/OUjRszXsUQP2E1iUdPUW9X3tHk=";
  18   };
  19   vendorHash = "sha256-a57RtK8PxwaRrSA6W6R//GacZ+pK8mBi4ZASS5NvShE=";
  20
  21   nativeBuildInputs = [ makeWrapper ];
  22
  23   ldflags = [
  24     "-X main.Version=${version}"
  25     "-X main.Tag=nixpkgs"
  26   ];
  27
  28   postInstall = ''
  29     wrapProgram $out/bin/aws-sso \
  30       --suffix PATH : ${lib.makeBinPath [ xdg-utils ]}
  31   '';
  32
  33   nativeCheckInputs = [ getent ];
  34
  35   checkFlags = let
  36     skippedTests = [
  37       "TestAWSConsoleUrl"
  38       "TestAWSFederatedUrl"
  39       "TestServerWithSSL" # https://github.com/synfinatic/aws-sso-cli/issues/1030 -- remove when version >= 2.x
  40     ] ++ lib.optionals stdenv.hostPlatform.isDarwin [ "TestDetectShellBash" ];
  41   in
  42     [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
  43
  44   meta = with lib; {
  45     homepage = "https://github.com/synfinatic/aws-sso-cli";
  46     description = "AWS SSO CLI is a secure replacement for using the aws configure sso wizard";
  47     license = licenses.gpl3Plus;
  48     maintainers = with maintainers; [ devusb ];
  49     mainProgram = "aws-sso";
  50   };
  51 }