pkgs/by-name/bc/bcachefs-tools/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   pkg-config,
   6   libuuid,
   7   libsodium,
   8   keyutils,
   9   liburcu,
  10   zlib,
  11   libaio,
  12   zstd,
  13   lz4,
  14   attr,
  15   udev,
  16   fuse3,
  17   cargo,
  18   rustc,
  19   rustPlatform,
  20   makeWrapper,
  21   nix-update-script,
  22   python3,
  23   testers,
  24   nixosTests,
  25   installShellFiles,
  26   fuseSupport ? false,
  27 }:
  28
  29 stdenv.mkDerivation (finalAttrs: {
  30   pname = "bcachefs-tools";
  31   version = "1.11.0";
  32
  33   src = fetchFromGitHub {
  34     owner = "koverstreet";
  35     repo = "bcachefs-tools";
  36     rev = "refs/tags/v${finalAttrs.version}";
  37     hash = "sha256-L2eIYdQnnmKNI8QWSy8nk4GzJ8jv+qt98gqdzcJH31Q=";
  38   };
  39
  40   nativeBuildInputs = [
  41     pkg-config
  42     cargo
  43     rustc
  44     rustPlatform.cargoSetupHook
  45     rustPlatform.bindgenHook
  46     makeWrapper
  47     installShellFiles
  48   ];
  49
  50   buildInputs = [
  51     libaio
  52     keyutils
  53     lz4
  54
  55     libsodium
  56     liburcu
  57     libuuid
  58     zstd
  59     zlib
  60     attr
  61     udev
  62   ] ++ lib.optional fuseSupport fuse3;
  63
  64   cargoDeps = rustPlatform.fetchCargoTarball {
  65     src = finalAttrs.src;
  66     hash = "sha256-Ol3wKdxKYJWDC/JREOfVSQRNnWVano7qilMRvqrLsgA==";
  67   };
  68
  69   makeFlags = [
  70     "PREFIX=${placeholder "out"}"
  71     "VERSION=${finalAttrs.version}"
  72     "INITRAMFS_DIR=${placeholder "out"}/etc/initramfs-tools"
  73   ] ++ lib.optional fuseSupport "BCACHEFS_FUSE=1";
  74
  75   env = {
  76     CARGO_BUILD_TARGET = stdenv.hostPlatform.rust.rustcTargetSpec;
  77     "CARGO_TARGET_${stdenv.hostPlatform.rust.cargoEnvVarTarget}_LINKER" = "${stdenv.cc.targetPrefix}cc";
  78   };
  79
  80   # FIXME: Try enabling this once the default linux kernel is at least 6.7
  81   doCheck = false; # needs bcachefs module loaded on builder
  82
  83   postPatch = ''
  84     substituteInPlace Makefile \
  85       --replace-fail "target/release/bcachefs" "target/${stdenv.hostPlatform.rust.rustcTargetSpec}/release/bcachefs"
  86   '';
  87
  88   preCheck = lib.optionalString (!fuseSupport) ''
  89     rm tests/test_fuse.py
  90   '';
  91   checkFlags = [ "BCACHEFS_TEST_USE_VALGRIND=no" ];
  92
  93   # Tries to install to the 'systemd-minimal' and 'udev' nix installation paths
  94   installFlags = [
  95     "PKGCONFIG_SERVICEDIR=$(out)/lib/systemd/system"
  96     "PKGCONFIG_UDEVDIR=$(out)/lib/udev"
  97   ];
  98
  99   postInstall =
 100     ''
 101       substituteInPlace $out/libexec/bcachefsck_all \
 102         --replace-fail "/usr/bin/python3" "${python3.interpreter}"
 103     ''
 104     + lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
 105       installShellCompletion --cmd bcachefs \
 106         --bash <($out/sbin/bcachefs completions bash) \
 107         --zsh  <($out/sbin/bcachefs completions zsh) \
 108         --fish <($out/sbin/bcachefs completions fish)
 109     '';
 110
 111   passthru = {
 112     tests = {
 113       version = testers.testVersion {
 114         package = finalAttrs.finalPackage;
 115         command = "${finalAttrs.meta.mainProgram} version";
 116         version = "${finalAttrs.version}";
 117       };
 118       smoke-test = nixosTests.bcachefs;
 119       inherit (nixosTests.installer) bcachefsSimple bcachefsEncrypted bcachefsMulti;
 120     };
 121
 122     updateScript = nix-update-script { };
 123   };
 124
 125   enableParallelBuilding = true;
 126
 127   meta = {
 128     description = "Tool for managing bcachefs filesystems";
 129     homepage = "https://bcachefs.org/";
 130     license = lib.licenses.gpl2Only;
 131     maintainers = with lib.maintainers; [
 132       davidak
 133       Madouura
 134     ];
 135     platforms = lib.platforms.linux;
 136     mainProgram = "bcachefs";
 137   };
 138 })