pkgs/by-name/bt/bt-migrate/package.nix

   1 { lib
   2 , boost
   3 , cmake
   4 , cxxopts
   5 , digestpp
   6 , fetchFromGitHub
   7 , fmt
   8 , jsoncons
   9 , pugixml
  10 , sqlite_orm
  11 , stdenv
  12 }:
  13 stdenv.mkDerivation {
  14   pname = "bt-migrate";
  15   version = "0-unstable-2023-08-17";
  16
  17   src = fetchFromGitHub {
  18     owner = "mikedld";
  19     repo = "bt-migrate";
  20     rev = "e15a489c0c76f98355586ebbee08223af4e9bf50";
  21     hash = "sha256-kA6yxhbIh3ThmgF8Zyoe3I79giLVmdNr9IIrw5Xx4s0=";
  22   };
  23
  24   nativeBuildInputs = [
  25     cmake
  26   ];
  27
  28   buildInputs = [
  29     boost
  30     cxxopts
  31     fmt
  32     jsoncons
  33     pugixml
  34     sqlite_orm
  35   ];
  36
  37   cmakeFlags = [
  38     (lib.strings.cmakeBool "USE_VCPKG" false)
  39     # NOTE: digestpp does not have proper CMake packaging (yet?)
  40     (lib.strings.cmakeBool "USE_FETCHCONTENT" true)
  41     (lib.strings.cmakeFeature "FETCHCONTENT_SOURCE_DIR_DIGESTPP" "${digestpp}/include/digestpp")
  42   ];
  43
  44   # NOTE: no install target in CMake...
  45   installPhase = ''
  46     runHook preInstall
  47
  48     mkdir -p $out/bin
  49     cp BtMigrate $out/bin
  50
  51     runHook postInstall
  52   '';
  53
  54   strictDeps = true;
  55
  56   meta = with lib; {
  57     description = "Torrent state migration tool";
  58     homepage = "https://github.com/mikedld/bt-migrate?tab=readme-ov-file";
  59     license = licenses.gpl3Only;
  60     maintainers = with maintainers; [ ambroisie ];
  61     mainProgram = "BtMigrate";
  62     platforms = platforms.all;
  63   };
  64 }